我总是发现很难阅读每行用关键字标记的注释:

REM blah blah blah

易于阅读:

:: blah blah blah

脚本所在的路径(带驱动器):~dp0

set BAT_HOME=%~dp0
echo %BAT_HOME%
cd %BAT_HOME%

子字符串变量:

> set str=0123456789
> echo %str:~0,5%
01234
> echo %str:~-5,5%
56789
> echo %str:~3,-3%
3456

PUSHD path

将您带到path指定的目录。

POPD

带您回到您“推”的目录。

FOR命令!虽然我讨厌写批处理文件，但我很感激它。

FOR /F "eol=; tokens=2,3* delims=, " %i in (myfile.txt) do @echo %i %j %k

将解析myfile.txt中的每一行，忽略以分号开头的行，将每行的第2和第3个标记传递给for主体，标记由逗号和/或空格分隔。 注意for语句引用%i获取第二个令牌，引用%j获取第三个令牌，引用%k获取第三个令牌之后的所有剩余令牌。

你也可以用它来遍历目录、目录内容等等…

整数运算:

> SET /A result=10/3 + 1
4

创建一个空文件:

> copy nul filename.ext

通过使用CALL, EXIT /B, SETLOCAL和ENDLOCAL可以实现带有局部变量的子例程。

例子:

@echo off

set x=xxxxx
call :sub 10
echo %x%
exit /b

:sub
setlocal
set /a x=%1 + 1
echo %x%
endlocal
exit /b

这将打印

11
xxxxx

尽管:sub修改了x。

PAUSE

停止执行并显示如下提示:

Press any key to continue . . .

如果你想通过在Windows资源管理器中双击一个批处理来运行它，并且想实际看到输出，而不仅仅是命令窗口的一闪而过，这很有用。

使用空格和转义字符完全控制输出:

echo.    ^<resourceDir^>/%basedir%/resources^</resourceDir^>

继续行:

call C:\WINDOWS\system32\ntbackup.exe ^
    backup ^
    /V:yes ^
    /R:no ^
    /RS:no ^
    /HC:off ^
    /M normal ^
    /L:s ^
    @daily.bks ^
    /F daily.bkf

子例程(输出42):

    @echo off
    call :answer 42
    goto :eof
:do_something
    echo %1
    goto :eof

子例程返回一个值(输出0、1、2，等等):

    @echo off
    setlocal enableextensions enabledelayedexpansion
    call :seq_init seq1
:loop1
    if not %seq1%== 10 (
        call :seq_next seq1
        echo !seq1!
        goto :loop1
    )
    endlocal
    goto :eof

:seq_init
    set /a "%1 = -1"
    goto :eof
:seq_next
    set /a "seq_next_tmp1 = %1"
    set /a "%1 = %seq_next_tmp1% + 1"
    set seq_next_tmp1=
    goto :eof

我发现你可以轻松地将命令输出重定向到文件中非常有用:

DIR *.txt > tmp.txt
DIR *.exe >> tmp.txt

单箭头创建或覆盖文件，双箭头追加文件。现在我可以在我的文本编辑器中打开tmp.txt，做各种各样的事情。

变量的延迟展开(为了更好地度量，还加入了子字符串):

    @echo off
    setlocal enableextensions enabledelayedexpansion
    set full=/u01/users/pax
:loop1
    if not "!full:~-1!" == "/" (
        set full2=!full:~-1!!full2!
        set full=!full:~,-1!
        goto :loop1
    )
    echo !full!
    endlocal

狡猾的等待N秒的技巧(不是cmd.exe的一部分，但不是额外的软件，因为它是Windows自带的)，参见ping行。您需要N+1个ping，因为第一个ping没有延迟。

    echo %time%
    call :waitfor 5
    echo %time%
    goto :eof
:waitfor
    setlocal
    set /a "t = %1 + 1"
    >nul ping 127.0.0.1 -n %t%
    endlocal
    goto :eof

输出一个空行:

echo.

'remove directory'上的子目录选项:

rd /s /q junk

对于具有数字计数器的循环(输出1到10):

for /l %i in (1,1,10) do echo %i

能够运行命令并处理输出(如bash中的'$()'的反引号)。

for /f %i in ('dir /on /b *.jpg') do echo --^> %i

如果文件名中有空格，可以这样写:

for /f "tokens=*" %i in ('dir /on /b *.jpg') do echo --^> %i

快速将Unicode文本文件(16bit/char)转换为ASCII DOS文件(8bit/char)。

C:\> type unicodeencoded.txt > dosencoded.txt

作为奖励，如果可能的话，字符会被正确映射。

不知道这在批处理文件中有多有用，但在命令提示符中使用它是一个非常方便的命令:

C:\some_directory> start .

这将在“some_directory”文件夹中打开Windows资源管理器。

我发现这非常节省时间。

如块状结构:

if "%VS90COMNTOOLS%"=="" (
  echo: Visual Studio 2008 is not installed
  exit /b
)

这里有一个技巧，我用它来连续运行My Nant Build脚本，而不必一遍又一遍地单击批处理文件。

:CODELINE
NANT.EXE -buildfile:alltargets.build -l:build.log build.product
@pause
GOTO :CODELINE

在您的解决方案完成构建之后，它将被暂停。然后，如果您按下任何键，它将再次重新运行构建脚本。我必须说非常方便。

softwarejedi已经提到了for命令，但我将再次提到它，因为它非常强大。

下面以YYYYMMDD格式输出当前日期，我在生成备份目录时使用此格式。

for /f "tokens=2-4 delims=/- " %a in ('DATE/T') do echo %c%b%a

隐藏从命令重定向到>nul 2>&1的所有输出。

例如，某些命令行程序即使重定向到>nul也会显示输出。但是，如果像下面这行那样重定向输出，所有输出都将被抑制。

PSKILL NOTEPAD >nul 2>&1

编辑:有关其工作原理的解释，请参见忽略命令的输出。

这里将介绍如何通过扫描给定目录来构建CLASSPATH。

setlocal ENABLEDELAYEDEXPANSION
if defined CLASSPATH (set CLASSPATH=%CLASSPATH%;.) else (set CLASSPATH=.)
FOR /R .\lib %%G IN (*.jar) DO set CLASSPATH=!CLASSPATH!;%%G
Echo The Classpath definition is %CLASSPATH%

适用于XP(或更好)。对于W2K，您需要使用两个BAT文件来实现相同的结果(请参阅在类路径定义中包含所有jar)。

在1.6版本中不需要它，因为你可以直接在CLASSPATH中指定通配符(例如-cp ".\lib*")。

一行中包含多个命令，在很多情况下都很有用:

&用于组合两个命令，执行command1和command2 &&一个条件组合，如果command1成功完成，则执行command2 仅当command1未成功完成时才执行Command2。

例子:

:: ** Edit the most recent .TXT file and exit, useful in a .CMD / .BAT **
FOR /F %%I IN ('DIR *.TXT /B /O:-N') DO NOTEPAD %%I & EXIT


:: ** If exist any .TXT file, display the list in NOTEPAD, if not it 
:: ** exits without any error (note the && and the 2> error redirection)
DIR *.TXT > TXT.LST 2> NUL && NOTEPAD TXT.LST

您可以将if语句链接起来，以获得类似短路布尔' and'的效果。

if foo if bar baz

文件名为“YYYY-MM-DD HH:MM:SS.txt”的例子

回波测试>“%日期:~ 0,4% - %日期:~ 5 2% - %日期:~ 8,2% %时间:~ 0,2% _ %时间:~ 3,2% _ %时间:~ 6,2% . txt”

我使用颜色来指示我的脚本是否成功，失败，或者通过改变文本和背景的颜色来需要一些输入。当你有一些机器在你视野范围内，但距离很远时，它真的很有帮助

颜色XY

其中X和Y为从0到F的十六进制值，其中X -背景，Y -文本，当X = Y时颜色不会改变。

颜色Z

更改文本颜色为“Z”并设置黑色背景，“颜色0”将不起作用

颜色的名字叫

颜色吗?

设置环境变量时的搜索和替换:

> @set fname=%date:/=%

.．.从日期中删除“/”以用于带时间戳的文件名。

还有子字符串……

> @set dayofweek=%fname:~0,3%

cmd.exe本身的/c参数，告诉它运行然后执行这些命令。

我曾经发现自己经常这样做:

win+r, cmd RETURN, ping google.com RETURN

但现在我只知道

win+r, cmd /c ping google.com返回

快得多。如果您正在使用pstools，并且希望使用psexec在远程机器上执行一些命令行功能，那么这也很有帮助。

EDIT: /k工作方式相同，但保持提示打开。这可能经常会派上用场。

cmd.exe中的快速编辑模式是我的最爱。这有点偏离主题，但是当与命令shell交互时，它可以是一个救星。不，我并不是在夸张——在你死之前，你只会看到一定次数的* * * * * v;你看得越多，死得越快。

打开regedit(小心，不是我的 故障、蓝屏等) 进入HKCU/控制台 “quickkedit”设置为“1”

(你也可以从UI设置，这可能是更好的方法。有关说明，请参阅注释。还有一个很好的一行脚本也可以做到这一点。)

现在，要复制，只需左键单击并拖动选择，然后右键单击复制。要粘贴，只需右击。

不再有^ v ^ v ^ v ^ v ^ v ^ v ^ v ^ v ^ v ^ v ^ v ^ v ^ v ^ v ^ v ^ v !!

该死，我想我刚杀了人。对不起!

逃离“管道”:

echo ^| ^< ^> ^& ^\ ^^

具有数值变量的循环的正确格式是

for /l %%i in (startNumber, counter, endNumber) do echo %%i

更多详情> http://www.ss64.com/nt/for.html

HELP

当使用不同的操作系统版本时，了解本机可用的命令是很重要的。在命令提示符处输入HELP可以显示可用的命令，以及它们的功能的简要描述。

cmd.exe /? 

这将列出用于启动命令提示符的所有命令行参数，以及更改整个系统行为的注册表调整。

而不是用REM或::行乱写脚本，我在每个脚本的顶部执行以下操作:

@echo OFF
goto :START

Description of the script.

Usage:
   myscript -parm1|parm2 > result.txt

:START

注意如何使用管道和重定向字符而不转义它们。

没有提供太多的功能，但是您可以将title命令用于一些用途，比如在任务栏中提供长脚本的状态，或者只是增强用户反馈。

@title Searching for ...
:: processing search
@title preparing search results
:: data processing

为了从脚本内部解析stdin，你需要使用For和FIND命令:

for /f "tokens=*" %%g in ('find /V ""') do (
     :: do what you want with %%g
     echo %%g
)

在脚本中使用命令扩展shell选项时，强烈建议您在脚本开始时执行以下技巧。

——从http://www.ss64.com/nt/setlocal.html粘贴的信息

如果给定一个参数，SETLOCAL将设置一个ERRORLEVEL。如果给出两个有效参数中的一个，它将为0，否则为1。 你可以在批处理文件中使用它来确定命令扩展名是否可用，使用以下技术:

VERIFY errors 2>nul
SETLOCAL ENABLEEXTENSIONS
IF ERRORLEVEL 1 echo Unable to enable extensions

这是因为“VERIFY errors”将ERRORLEVEL设置为1，然后如果扩展不可用(例如，如果脚本在command.com下运行)，SETLOCAL将无法重置ERRORLEVEL值。 如果命令扩展被永久禁用，那么SETLOCAL ENABLEEXTENSIONS将不会恢复它们。

稍后可以使用call对名称求值，从而得到一些有用的属性。

call set SomeEnvVariable_%extension%=%%%somevalue%%%

使用调用来设置名称依赖于其他变量的变量。如果与某些变量命名规则一起使用，则可以通过使用谨慎的命名规则来模拟数组或字典等数据集合。somevalue周围的三个%是这样的，它将在调用之后和调用set之前计算为一个变量名，周围是一个%。这意味着一行中的两个%转义为一个%字符，然后它将再次展开它，因此somevalue实际上是一个名称指针。

call set TempVar=%%SomeEnvVariable_%extension%%%

将它与一个临时变量一起使用以检索值，然后可以在逻辑中使用该值。这在与延迟变量展开一起使用时非常有用。

要正确使用此方法，需要启用延迟变量扩展。因为它在默认情况下是关闭的，所以最好在脚本中启用它，将其作为第一个指令之一:

setlocal EnableDelayedExpansion

一个非常古老(大约1990年)的技巧来获得环境变量的总大小:

set > test
dir test
del test

这个批处理文件既可以使用简单文件，也可以使用目录作为命令行参数(您可以以任何顺序混合它们)。循环在任何指定的文件上运行命令(本例中为'echo')，如果一个参数是一个目录，它将在其中的每个文件上递归地运行命令。

@echo off
for /f "delims=" %%f in ('dir %* /a-d /b /s') do echo %%f

命令分隔符:

cls & dir
copy a b && echo Success
copy a b || echo Failure

在第二行，&&之后的命令仅在第一个命令成功时运行。

在第3行，||之后的命令仅在第一个命令失败时运行。

SHIFT

这是一种在命令行上迭代传递到脚本(或子例程)的可变数量的参数的方法。在最简单的用法中，它将%2转换为%1，将%3转换为%2，依此类推。(你也可以传递一个参数给SHIFT来跳过多个参数。)这使得命令具有“破坏性”(即%1永远消失)，但它允许您避免硬编码支持的参数的最大数量。

下面是一个简短的例子，一次处理一个命令行参数:

:ParseArgs

if "%1"=="" (
    goto :DoneParsingArgs
)

rem ... do something with %1 ...

shift

goto :ParseArgs


:DoneParsingArgs

rem ...

允许您更改目录基于环境变量没有 必须指定'%'指令。如果指定的变量没有 存在，然后尝试目录名。

@if defined %1 (call cd "%%%1%%") else (call cd %1)

相当于bash(和其他shell)

echo -n Hello # or
echo Hello\\c

输出“Hello”，后面没有换行符。一个cmd黑客来做这个:

<nul set /p any-variable-name=Hello

Set /p是一种提示用户输入的方法。它发出给定的字符串，然后等待(在同一行，即没有CRLF)，等待用户输入响应。

<nul只是向set /p命令输送一个空响应，因此最终结果是发出的提示字符串。(由于响应为空，所使用的变量保持不变。)

问题是:不可能输出前导等号，在Vista中前导空白字符被删除，但在XP中没有。

搜索路径上的可执行文件(或其他类似路径的字符串，如果需要):

c:\> for %i in (cmd.exe) do @echo. %~$PATH:i
C:\WINDOWS\system32\cmd.exe

c:\> for %i in (python.exe) do @echo. %~$PATH:i
C:\Python25\python.exe

c:\>

关于使用::而不是REM进行评论:要小心!::是CALL标签的一种特殊情况，作用类似于注释。当在括号内使用时，例如在for或IF循环中，函数将提前退出。调试非常令人沮丧!

详细描述请参见http://www.ss64.com/nt/rem.html。

(添加一个新的答案，而不是上面第一次提到的评论，因为我还不值得评论:0)

CHOICE命令提示用户在多个选项中选择一个(通过单个按键)

@echo off
echo Please choose one of the following options
echo 1. Apple
echo 2. Orange
echo 3. Pizza
echo a, b, c. Something else
choice /c:123abc /m "Answer?"
set ChoiceLevel=%ErrorLevel%
echo Choice was: %ChoiceLevel%

%ChoiceLevel%将是选中的第n个选项(在上面的例子中，b=5)。

更多详情请访问SS64.com上的CHOICE参考页面。

将输出重定向到控制台，即使批处理的输出已经通过> con语法重定向到文件。

例子: foo.cmd:

echo a
echo b > con

调用:

foo.cmd > output.txt

这将导致“a”输出到output.txt，而“b”输出到控制台。

前面已经提到了%~dp0部分，但实际上还有更多内容: ~之后的字符定义了提取的信息。 返回补丁文件名时不包含字母 D -返回驱动器号 P -返回路径 S -返回短路径 X -返回文件扩展名 如果你在c:\Temp\long dir name\文件夹中执行test.bat脚本，

@echo off
echo %0
echo %~d0
echo %~p0
echo %~dp0
echo %~x0
echo %~s0
echo %~sp0

您将得到以下输出

测验 c: \Temp\长目录名\ c:\Temp\长目录名\ 。bat c: \ Temp \ \ test.bat LONGDI ~ 1 1 \ \ Temp \ LONGDI ~

如果一个参数被传递到你的脚本中 测试c: \ temp \ mysrc \ test.cpp 同样的操作也可以用于%1变量。

但是%0扩展的结果取决于位置! 在批处理的“顶层”，它扩展到当前批处理文件名。 在函数(调用)中，它展开为函数名。

@echo off
echo %0
call :test
goto :eof

:test
echo %0
echo %~0
echo %~n0

输出是(批处理文件以myBatch.bat开始)

myBatch.bat
:test
:test
myBatch

没有编辑器，需要创建一个批处理文件?

copy con test.bat

只需输入命令，按enter键输入新行。 按Ctrl-Z和Enter关闭文件。

IF命令!没有它，我的批处理文件是垃圾!

@echo off
IF exist %windir%\system32\iexplore.exe goto end

echo Hmm... it seems you do not have Internet Explorer.
echo Great! You seem to understand ;)

:end
echo Hmm... You have Internet Explorer.
echo That is bad :)

我真的很喜欢这个Windows XP命令参考，以及在顶部的语法链接;它涵盖了许多已经在其他答案中找到的技巧和技巧。

抽取随机的文本行

@echo off

:: Get time (alas, it's only HH:MM xM

for /f %%a in ('time /t') do set zD1=%%a



:: Get last digit of MM

set zD2=%zD1:~4,1%



:: Seed the randomizer, if needed

if not defined zNUM1 set /a zNUM1=%zD2%


:: Get a kinda random number

set /a zNUM1=zNUM1 * 214013 + 2531011

set /a zNUM2=zNUM1 ^>^> 16 ^& 0x7fff


:: Pull off the first digit

:: (Last digit would be better, but it's late, and I'm tired)

set zIDX=%zNUM2:~0,1%


:: Map it down to 0-3

set /a zIDX=zIDX/3


:: Finally, we can set do some proper initialization

set /a zIIDX=0

set zLO=

set zLL=""


:: Step through each line in the file, looking for line zIDX

for /f "delims=@" %%a in (c:\lines.txt) do call :zoo  %zIDX%  %%a


:: If line zIDX wasn't found, we'll settle for zee LastLine

if "%zLO%"=="" set zLO=%zLL%

goto awdun


:: See if the current line is line zIDX

:zoo


:: Save string of all parms

set zALL=%*


:: Strip off the first parm (sure hope lines aren't longer than 254 chars)

set zWORDS=%zALL:~2,255%


:: Make this line zee LastLine

set zLL=%zWORDS%


:: If this is the line we're looking for, make it zee LineOut

if {%1}=={%zIIDX%} set zLO=%zWORDS%


:: Keep track of line numbers

set /a zIIDX=%zIIDX% + 1

goto :eof




:awdun

echo ==%zLO%==


:: Be socially responsible

set zALL=

set zD1=

set zD2=

set zIDX=

set zIIDX=

set zLL=

set zLO=

:: But don't mess with seed

::set zNUM1=

set zNUM2=

set zWORDS=

我想说DEBUG.EXE是批处理文件中一个非常有用但却未被充分利用的特性。

DEBUG命令允许你…

汇编和反汇编16位代码 读/写内存(现代受保护的内存使这个功能变得不那么有用。) 从硬盘读取数据扇区，原始 十六进制编辑

简而言之，这个工具非常强大。现在可能已经不怎么使用了，但是从批处理脚本调用和控制这个功能的能力为批处理脚本增加了惊人的能力。

注意:据我所知，微软已经从64位版本的Windows Xp和Vista中删除了这个命令，并打算从Windows 7中完全删除它。

There is also the EDLIN command. While it may be an old bastard tool once used for line-based text editing, the fact that it's controllable from the command line makes it rather useful for batch scripting, mostly because, just like any other case you'd be using EDLIN, it's the only tool available. After all, EDLIN is not a tool you would ordinarily want to use for text editing, unless you are somewhat masochistic. To quote Tim Patterson (the fellow who wrote it): "I was aghast when I heard that IBM was using it and not throwing it out the window."

注意:EDLIN将老式的EOF (1A)标记添加到它编辑的文件中。如果需要删除它们，可能必须使用DEBUG。

现在很多人使用GOTO:EOF来终止他们的批处理文件，但你也可以使用EXIT /B来达到这个目的。

使用EXIT /B的优点是你可以在EXIT /B之后添加一个错误级别，它将退出该错误级别。

使用SET /P从文件中设置环境变量

SET /P SVNVERSION=<ver.tmp

ENDLOCAL使用的行仍然解析局部变量。这就允许了以下技巧:

ENDLOCAL & SET MYGLOBAL=%SOMELOCAL% & SET MYOTHERGLOBAL=%SOMEOTHERLOCAL%

这是一种将结果传输到调用上下文的有用方法。具体来说，一旦ENDLOCAL完成，% somlocal%就超出了作用域，但那时% somlocal%已经展开，因此MYGLOBAL在调用上下文中使用局部变量赋值。

出于同样的原因，如果你决定这样做:

ENDLOCAL & SET MYLOCAL=%MYLOCAL%

您将发现新的MYLOCAL变量现在实际上是一个常规环境变量，而不是您希望它成为的局部变量。

将错误级别设置为你想要的任何数字的方法:

CMD /C EXIT number

去:eof纸板

我在脚本的末尾添加了“goto:eof”，作为存放代码片段的方便空间。这样我就可以快速复制/粘贴到这个区域，而不需要注释/取消注释。

goto :eof
:: code scraps
call this.bat
call that.bat
set TS=%DATE:~10%%DATE:~4,2%%DATE:~7,2%-%TIME:~0,2%%TIME:~3,2%%TIME:~6%%
for /R C:\temp\ %%G in (*.bak) DO del %%G

当你想在分支之间复制文件时，一个方便的技巧:

C:\src\branch1\mydir\mydir2\mydir3\mydir4>xcopy %cd:branch1=branch2%\foo*
Overwrite C:\src\branch1\mydir\mydir2\mydir3\mydir4\foo.txt (Yes/No/All)? y
C:\src\branch2\mydir\mydir2\mydir3\mydir4\foo.txt

这既使用了%cd%环境变量，也使用了环境变量替换。

当向批处理文件传递未知数量的参数时，例如，当几个文件被拖放到批处理文件上以启动批处理文件时，您可以通过名称引用每个参数变量。

TYPE %1
TYPE %2
TYPE %3
TYPE %4
TYPE %5
...etc

但是当你想要检查每个参数是否存在时，这就变得非常混乱了:

if [%1] NEQ [] (
TYPE %1
)
if [%2] NEQ [] (
TYPE %2
)
if [%3] NEQ [] (
TYPE %3
)
if [%4] NEQ [] (
TYPE %4
)
if [%5] NEQ [] (
TYPE %5
)
...etc

此外，使用这种方法只能接受有限数量的参数。

相反，尝试使用SHIFT命令:

:loop
IF [%1] NEQ [] (
TYPE %1
) ELSE (
GOTO end
)
SHIFT
GOTO loop
:end

SHIFT将把所有参数都向下移动一个，因此%2变成%1，%3变成%2，等等。

FIND作为grep的替代品。 我用find给自己黑了个电话簿。非常有用:

@echo off
:begin
set /p term=Enter query: 
type phonebookfile.txt |find /i "%term%"
if %errorlevel% == 0 GOTO :choose
echo No entry found
set /p new_entry=Add new entry: 
echo %new_entry% >> phonebookfile.txt 
:choose
set /p action=(q)uit, (n)ew query or (e)dit? [q] 
if "%action%"=="n" GOTO anfang
if "%action%"=="e" (
    notepad phonebookfile.txt
    goto :choose
)

非常快速有效。

可以使用errorlevel检查批处理文件将要运行的系统(当前目录或路径)上是否存在给定的程序。为了让测试的程序正常运行，退出并设置退出码。在这个例子中，我用了-?作为myExe的参数，大多数CLI程序都有类似的参数，如-h，——help， -v等…这确保它只是运行并退出，并将错误级别设置为0

myExe -? >nul 2>&1 
Set errCode=%errorlevel%
@if %errCode% EQU 0 (
    echo myExe -? does not return an error (exists)
) ELSE (
    echo myExe -? returns an error (does not exist)
)

是的，你可以直接测试errorlevel，而不是将其分配给errCode，但是这样你就可以在测试和条件之间使用命令，并根据需要反复测试条件。

调用集——将环境变量展开几个层次。

在http://ss64.com/nt/call.html#advanced从另一个SO问题的答案中发现这个批处理文件变量在for循环中初始化

set VarName=Param
set Param=This

call set Answer=%%%Varname%%%
Echo %Answer%

给了

set VarName=Param
set Param=This
call set Answer=%Param%
Echo This
This

隐藏交互式批处理脚本的输入:

  @echo off

  echo hP1X500P[PZBBBfh#b##fXf-V@`$fPf]f3/f1/5++u5>in.com

  set /p secret_password="Enter password:"<nul

  for /f "tokens=*" %%i in ('in.com') do (set secret_password=%%i)

  del in.com

使用&::的内联注释。

:: This is my batch file which does stuff.
copy thisstuff thatstuff  &:: We need to make a backup in case we screw up!

:: ... do lots of other stuff

这是如何工作的呢?这是一个丑陋的黑客。&是命令分隔符，大致近似于;UNIX shell。::是另一个丑陋的黑客，有点像REM语句。最终结果是执行命令，然后执行一个什么都不做的命令，从而近似于注释。

这并不是在所有情况下都有效，但它通常足够有用。

列出所有驱动器:

fsutil fsinfo drives

获取当前的日、月和年(独立于locale):

for /f "tokens=1-4 delims=/-. " %%i in ('date /t') do (call :set_date %%i %%j %%k %%l)
goto :end_set_date

:set_date
if ("%1:~0,1%" gtr "9") shift
for /f "skip=1 tokens=2-4 delims=(-)" %%m in ('echo,^|date') do (set %%m=%1&set %%n=%2&set %%o=%3)
goto :eof

:end_set_date

echo day in 'DD' format is %dd%; month in 'MM' format is %mm%; year in 'YYYY' format is %yy%

无论如何，这是一个很好的Windows CMD或批处理文件的在线参考。我学到了一些我不知道的东西。

创建并开始编辑一个新文件

copy con new.txt
This is the contents of my file
^Z

Ctrl+Z发送ASCII EOF字符。这就像bash中的heredocs:

cat <<EOF > new.txt
This is the contents of my file
EOF

删除周围的报价。

for /f "useback tokens=*" %%a in ('%str%') do set str=%%~a

我最近必须写一个批处理文件，由VS预构建事件调用，我想在项目目录中作为参数传递。在批处理文件中，我需要将路径与嵌套子文件夹名称连接起来，但首先需要删除周围的引号。

Forfiles非常有用，例如，递归删除所有超过两天的文件

forfiles /D -2 /P "C:\Temp" /S /C "cmd /c del @path"

支持正则表达式的Findstr:

findstr "^[0-9].*" c:\windows\system32\drivers\etc\hosts

犯错就放弃。

IF "%errorlevel%" NEQ "0" (
   echo "ERROR:  Something broke.  Bailing out."
   exit /B 1
)

使用pushd到UNC路径将创建一个临时驱动器映射(从Z开始，向后查找下一个可用的字母)，并将您放入该驱动器和路径中。弹出或退出命令提示符时，临时映射将消失。

   C:\>pushd \\yourmom\jukebox

   Z:\>pushd \\yourmom\business

   Y:\>

此外，与其说这是一个批处理技巧，不如说这是一个命令行环境技巧，但是当您在命令行上使用pushd和popd和网络共享时，使用$+(显示pushd堆栈深度)和$M(显示网络共享路径)修改提示符是有用的。

   C:\utils>prompt $+$m$p$g

   C:\utils>pushd m:

   +\\yourmom\pub M:\>pushd c:\

   ++c:\>pushd
   M:\
   C:\utils  

   ++c:\>popd

   +\\yourmom\pub M:\>popd

   C:\utils>

使用管道'|'命令查找文件夹中的文件中的字符串:

dir /b *.* | findstr /f:/ "thepattern"

符号链接:

mklink /d directorylink ..\realdirectory
mklink filelink realfile

该命令是Windows Server 2008及更新版本(包括Vista和Windows 7)上的本机命令。(它也包含在一些Windows资源包中。)

基于行的执行

虽然在大多数情况下没有明显的好处，但当试图在运行时更新内容时，它会有所帮助。例如:

UpdateSource.bat

copy UpdateSource.bat Current.bat
echo "Hi!"

Current.bat

copy UpdateSource.bat Current.bat

现在，执行Current.bat会产生这样的输出。

HI!

注意，批处理执行是按行号进行的。如果基本行没有完全相同的行号，这样的更新可能会导致跳过或向后移动一行。

使用copy追加文件:

copy file1.txt+file2.txt+file3.txt append.txt

另外，将所有CLI参数设置为一个变量:

SET MSG=%*

这将使用空格分隔的每个单词(或符号)并将其保存到单个批处理文件变量中。从技术上讲，每个参数都是%1、%2、$3等等，但是这个SET命令使用通配符来引用stdin中的每个参数。

批处理文件:

@SET MSG=%*
@echo %MSG%

命令行:

C:\test>test.bat Hello World!
Hello World!

递归搜索目录树中的字符串:

findstr /S /C:"string literal" *.*

你也可以使用正则表达式:

findstr /S /R "^ERROR" *.log

递归文件搜索:

dir /S myfile.txt

我使用它们作为常用目录的快捷方式。 一个名为“sandbox.bat”的示例文件，它位于我的PATH目录中

EXPLORER "C:\Documents and Settings\myusername\Desktop\sandbox"

调用脚本只需WIN+R—>沙盒

要获取当前日期/时间用于日志文件等，我在批处理文件中使用这个:

for /f "usebackq tokens=1,2,3,4,5,6,7 delims=/:. " %%a in (`echo %DATE% %TIME%`) do set NOW=%%d%%b%%c_%%e%%f%%g
set LOG=output_%NOW%.log

要从文件的第一行开始设置一个环境变量，我使用以下命令:

rem a.txt contains one line: abc123
set /p DATA=<a.txt
echo data: %DATA%

这将输出:abc123

批处理文件中的数组。

设置一个值:

set count=1
set var%count%=42

在命令行提取一个值:

call echo %var%count%%

从批处理文件中提取一个值:

call echo %%var%count%%%

注意额外的扫射%符号。

这项技术可能看起来有点复杂，但它非常有用。如上所述，将打印var1(即42)的内容。如果我们想将其他变量设置为var1中的值，也可以用set替换echo命令。这意味着下面的值在命令行是有效的赋值:

call set x=%var%count%%

然后查看va1的值:

echo %x%

dos命令宏。

我已经很久没有参考过这一点了，但我仍然认为这是一个好主意，值得分享。

我们可以将批处理文件和doskey脚本合并到一个文件中。这可能看起来有点过于聪明，但它确实有效。

;= @echo off
;= rem Call DOSKEY and use this file as the macrofile
;= %SystemRoot%\system32\doskey /listsize=1000 /macrofile=%0%
;= rem In batch mode, jump to the end of the file
;= goto end

;= Doskey aliases
h=doskey /history

;= File listing enhancements
ls=dir /x $*

;= Directory navigation
up=cd ..
pd=pushd

;= :end
;= rem ******************************************************************
;= rem * EOF - Don't remove the following line.  It clears out the ';' 
;= rem * macro. Were using it because there is no support for comments
;= rem * in a DOSKEY macro file.
;= rem ******************************************************************
;=

它通过定义一个假的doskey宏';'来工作，当它被解释为批处理文件时，它会被优雅地(或无声地)忽略。

我缩短了这里列出的版本，如果你想要更多，请点击这里。

批处理脚本最常见的需求之一是记录生成的输出，以供以后检查。是的，您可以将stdout和stderr重定向到一个文件，但是您无法看到发生了什么，除非您跟踪日志文件。

因此，考虑使用stdout/stderr日志记录工具运行您的批处理脚本，例如logger，它将使用时间戳记录输出，并且您仍然能够看到脚本进程。

另一个stdout/stderr日志记录实用程序

Yet another stdout/stderr logging utility [2010-08-05]
Copyright (C) 2010 LoRd_MuldeR <MuldeR2@GMX.de>
Released under the terms of the GNU General Public License (see License.txt)

Usage:
  logger.exe [logger options] : program.exe [program arguments]
  program.exe [program arguments] | logger.exe [logger options] : -

Options:
  -log <file name>  Name of the log file to create (default: "<program> <time>.log")
  -append           Append to the log file instead of replacing the existing file
  -mode <mode>      Write 'stdout' or 'stderr' or 'both' to log file (default: 'both')
  -format <format>  Format of log file, 'raw' or 'time' or 'full' (default: 'time')
  -filter <filter>  Don't write lines to log file that contain this string
  -invert           Invert filter, i.e. write only lines to log file that match filter
  -ignorecase       Apply filter in a case-insensitive way (default: case-sensitive)
  -nojobctrl        Don't add child process to job object (applies to Win2k and later)
  -noescape         Don't escape double quotes when forwarding command-line arguments
  -silent           Don't print additional information to the console
  -priority <flag>  Change process priority (idle/belownormal/normal/abovenormal/high)
  -inputcp <cpid>   Use the specified codepage for input processing (default: 'utf8')
  -outputcp <cpid>  Use the specified codepage for log file output (default: 'utf8')

就像上面一样，使用CALL, EXIT /B, SETLOCAL和ENDLOCAL，你可以用局部变量和返回值来实现函数。

例子:

@echo off

set x=xxxxx
call :fun 10
echo "%x%"
echo "%y%"
exit /b

:fun
setlocal
set /a y=%1 + 1
endlocal & set x=%y%
exit /b

这将打印:

"11"
""

y变量永远不会离开局部作用域，但由于CMD一次解析一行的方式，您可以将值提取到父作用域的x变量中。

您可以在批处理文件运行时修改它。例如，如果您希望在批处理文件退出之前看到结果，您可以在文件运行时在文件的末尾添加一个被遗忘的暂停。

请参见在批处理文件运行时更改批处理文件

我个人认为这更像是一个陷阱，而不是一个功能。