为了从脚本内部解析stdin，你需要使用For和FIND命令:

for /f "tokens=*" %%g in ('find /V ""') do (
     :: do what you want with %%g
     echo %%g
)

Forfiles非常有用，例如，递归删除所有超过两天的文件

forfiles /D -2 /P "C:\Temp" /S /C "cmd /c del @path"

现在很多人使用GOTO:EOF来终止他们的批处理文件，但你也可以使用EXIT /B来达到这个目的。

使用EXIT /B的优点是你可以在EXIT /B之后添加一个错误级别，它将退出该错误级别。

将错误级别设置为你想要的任何数字的方法:

CMD /C EXIT number

狡猾的等待N秒的技巧(不是cmd.exe的一部分，但不是额外的软件，因为它是Windows自带的)，参见ping行。您需要N+1个ping，因为第一个ping没有延迟。

    echo %time%
    call :waitfor 5
    echo %time%
    goto :eof
:waitfor
    setlocal
    set /a "t = %1 + 1"
    >nul ping 127.0.0.1 -n %t%
    endlocal
    goto :eof

dos命令宏。

我已经很久没有参考过这一点了，但我仍然认为这是一个好主意，值得分享。

我们可以将批处理文件和doskey脚本合并到一个文件中。这可能看起来有点过于聪明，但它确实有效。

;= @echo off
;= rem Call DOSKEY and use this file as the macrofile
;= %SystemRoot%\system32\doskey /listsize=1000 /macrofile=%0%
;= rem In batch mode, jump to the end of the file
;= goto end

;= Doskey aliases
h=doskey /history

;= File listing enhancements
ls=dir /x $*

;= Directory navigation
up=cd ..
pd=pushd

;= :end
;= rem ******************************************************************
;= rem * EOF - Don't remove the following line.  It clears out the ';' 
;= rem * macro. Were using it because there is no support for comments
;= rem * in a DOSKEY macro file.
;= rem ******************************************************************
;=

它通过定义一个假的doskey宏';'来工作，当它被解释为批处理文件时，它会被优雅地(或无声地)忽略。

我缩短了这里列出的版本，如果你想要更多，请点击这里。