如果你担心安全/密码盗窃(导致你设计这个解决方案,需要登录凭证在执行而不是静态的硬编码不需要数据库),然后您可以存储api或一半密码解密的代码或程序文件解密密钥,所以在运行时,用户将在控制台输入用户名/密码散列/解密之前传递给程序代码执行通过设置/ p,如果你查看在运行时用户输入凭据。

如果您正在运行一个脚本，使用不同的用户/密码运行程序，那么命令行参数将适合您。

如果您正在制作一个测试文件来查看不同登录的输出/效果，那么您可以将所有登录存储在一个加密文件中，作为参数传递给test。Cmd，除非你想坐在命令行并输入所有的登录，直到完成。

可以提供的参数数量限制为命令行上的字符总数。为了克服这一限制，上一段技巧是一种变通方法，不会有暴露用户密码的风险。

成对的参数

如果你喜欢在键值对中传递参数，你可以使用这样的方法:

@echo off

setlocal enableDelayedExpansion

:::::  asigning arguments as a key-value pairs:::::::::::::
set counter=0
for %%# in (%*) do (    
    set /a counter=counter+1
    set /a even=counter%%2
    
    if !even! == 0 (
        echo setting !prev! to %%#
        set "!prev!=%%~#"
    )
    set "prev=%%~#"
)
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

:: showing the assignments
echo %one% %two% %three% %four% %five%

endlocal

举个例子:

c:>argumentsDemo.bat one 1 "two" 2 three 3 four 4 "five" 5
1 2 3 4 5

预定义的变量

您还可以提前设置一些环境变量。这可以通过在控制台或在我的电脑上设置来完成:

@echo off

if defined variable1 (
    echo %variable1%
)

if defined variable2 (
    echo %variable2%
)

像这样称呼它:

c:\>set variable1=1

c:\>set variable2=2

c:\>argumentsTest.bat
1
2

包含列出值的文件

您还可以指向预先设置所需值的文件。 如果这是脚本:

@echo off

setlocal
::::::::::
set "VALUES_FILE=E:\scripts\values.txt"
:::::::::::


for /f "usebackq eol=: tokens=* delims=" %%# in ("%VALUES_FILE%") do set "%%#"

echo %key1% %key2% %some_other_key%

endlocal

values文件是这样的:

:::: use EOL=: in the FOR loop to use it as a comment

key1=value1

key2=value2

:::: do not left spaces arround the =
:::: or at the begining of the line

some_other_key=something else

and_one_more=more

调用它的输出将是:

Value1 value2别的东西

当然，您可以结合所有方法。检查参数语法，shift

要在命令行中引用一个set变量，你需要使用%a%，例如:

set a=100 
echo %a%  
rem output = 100 

注意:这适用于Windows 7 pro。

受到@Jon在其他地方的回答的启发，我设计了一个更通用的算法来提取命名参数、可选值和开关。

假设我们想要实现一个实用程序foobar。它需要一个初始命令。它有一个可选参数——foo，它接受一个可选值(当然不能是另一个参数);如果缺少该值，则默认为default。它还有一个可选参数——bar，它接受一个必需的值。最后，它可以带一个标志——baz，不允许有任何值。哦，这些参数可以以任何顺序出现。

换句话说，它看起来像这样:

foobar <command> [--foo [<fooval>]] [--bar <barval>] [--baz]

这里有一个解决方案:

@ECHO OFF
SETLOCAL
REM FooBar parameter demo
REM By Garret Wilson

SET CMD=%~1

IF "%CMD%" == "" (
  GOTO usage
)
SET FOO=
SET DEFAULT_FOO=default
SET BAR=
SET BAZ=

SHIFT
:args
SET PARAM=%~1
SET ARG=%~2
IF "%PARAM%" == "--foo" (
  SHIFT
  IF NOT "%ARG%" == "" (
    IF NOT "%ARG:~0,2%" == "--" (
      SET FOO=%ARG%
      SHIFT
    ) ELSE (
      SET FOO=%DEFAULT_FOO%
    )
  ) ELSE (
    SET FOO=%DEFAULT_FOO%
  )
) ELSE IF "%PARAM%" == "--bar" (
  SHIFT
  IF NOT "%ARG%" == "" (
    SET BAR=%ARG%
    SHIFT
  ) ELSE (
    ECHO Missing bar value. 1>&2
    ECHO:
    GOTO usage
  )
) ELSE IF "%PARAM%" == "--baz" (
  SHIFT
  SET BAZ=true
) ELSE IF "%PARAM%" == "" (
  GOTO endargs
) ELSE (
  ECHO Unrecognized option %1. 1>&2
  ECHO:
  GOTO usage
)
GOTO args
:endargs

ECHO Command: %CMD%
IF NOT "%FOO%" == "" (
  ECHO Foo: %FOO%
)
IF NOT "%BAR%" == "" (
  ECHO Bar: %BAR%
)
IF "%BAZ%" == "true" (
  ECHO Baz
)

REM TODO do something with FOO, BAR, and/or BAZ
GOTO :eof

:usage
ECHO FooBar
ECHO Usage: foobar ^<command^> [--foo [^<fooval^>]] [--bar ^<barval^>] [--baz]
EXIT /B 1

使用SETLOCAL，这样变量就不会转义到调用环境。 不要忘记初始化变量SET FOO=等，以防有人在调用环境中定义了它们。 使用%~1删除引号。 使用IF "%ARG%" == ""，而不是IF [%ARG%] ==[]，因为[和]不会使用以空格结尾的值。 即使你在if块内SHIFT，当前的参数如%~1也不会被更新，因为它们是在解析if时确定的。您可以在IF块中使用%~1和%~2，但这将令人困惑，因为您有一个SHIFT。你可以把SHIFT放在块的末尾，但这可能会丢失和/或混淆人们。所以“捕获”块外的%~1和%~1似乎是最好的。 你不想用一个参数来代替另一个参数的可选值，所以你必须检查IF NOT "%ARG:~0,2%" == "——"。 当您使用其中一个参数时，请注意只使用SHIFT。 重复的代码SET FOO=%DEFAULT_FOO%是令人遗憾的，但另一种选择是在IF NOT "%ARG%" == ""块之外添加一个IF "%FOO%" == "" SET FOO=%DEFAULT_FOO%。然而，因为它仍然在IF "%PARAM%" == "——foo"块中，% foo %的值将在你进入块之前被计算和设置，所以你永远不会检测到——foo参数存在，而且% foo %的值缺失。 注意ECHO缺失条值。1>&2向stderr发送错误消息。 想在Windows批处理文件中使用空行?你必须使用ECHO:或其中一种变体。

没有必要把事情复杂化。例如，它只是命令%1 %2参数，

@echo off

xcopy %1 %2 /D /E /C /Q /H /R /K /Y /Z

echo copied %1 to %2

pause

“pause”显示批处理文件所做的工作，并等待您按下ANY键。将其保存为Windows文件夹中的xx.bat。

要使用它，输入，例如:

xx c:\f\30\*.* f:\sites\30

这个批处理文件负责所有必要的参数，比如只复制文件、更新的文件等等。在Windows出现之前，我就开始使用它了。如果您喜欢在复制文件时查看文件名，可以省略Q参数。

另一个有用的技巧是使用%*表示“所有”。例如:

echo off
set arg1=%1
set arg2=%2
shift
shift
fake-command /u %arg1% /p %arg2% %*

跑步时:

test-command admin password foo bar

上面的批处理文件将运行:

fake-command /u admin /p password admin password foo bar

我的语法可能有点错误，但这是大意。