是的，在使用if和for和the gang时，不要忘记使用%%1这样的变量。

如果您忘记使用double %，那么您将替换(可能为空)命令行参数，并且您将收到一些非常令人困惑的错误消息。

另一个有用的技巧是使用%*表示“所有”。例如:

echo off
set arg1=%1
set arg2=%2
shift
shift
fake-command /u %arg1% /p %arg2% %*

跑步时:

test-command admin password foo bar

上面的批处理文件将运行:

fake-command /u admin /p password admin password foo bar

我的语法可能有点错误，但这是大意。

如果你想智能地处理缺失的参数，你可以这样做:

IF %1.==. GOTO No1
IF %2.==. GOTO No2
... do stuff...
GOTO End1

:No1
  ECHO No param 1
GOTO End1
:No2
  ECHO No param 2
GOTO End1

:End1

我是这样做的:

@fake-command /u %1 /p %2

下面是命令的样子:

test.cmd admin P@55w0rd > test-log.txt

%1应用于第一个参数，%2(这是棘手的部分)应用于第二个参数。您最多可以通过这种方式传递9个参数。

创建一个新的批处理文件(例如:openclass.bat)，并在文件中写入这一行:

java %~n1

然后将批处理文件放在system32文件夹中，找到你的Java类文件，右键单击，Properties, Open with…，然后找到你的批处理文件，选择它，这就是…

这对我很管用。

PS:当我关闭Java类时，我找不到关闭cmd窗口的方法。现在……

访问批处理参数可以简单地使用%1，%2，…%9或%*， 但前提是内容简单。

对于像“&”^&这样的复杂内容，没有简单的方法，因为不可能访问%1而不产生错误。

set  var=%1
set "var=%1"
set  var=%~1
set "var=%~1"

这些线延伸到

set  var="&"&
set "var="&"&"
set  var="&"&
set "var="&"&"

并且每一行都失败，因为其中一个&在引号之外。

这可以通过从临时文件中读取参数的注释版本来解决。

@echo off
SETLOCAL DisableDelayedExpansion

SETLOCAL
for %%a in (1) do (
    set "prompt="
    echo on
    for %%b in (1) do rem * #%1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'

诀窍是在rem语句后启用echo并展开%1(也适用于%2 ..% *)。 因此，即使是“&”&也可以被重复而不会产生错误，正如上面所说的那样。

但是为了能够重定向echo on的输出，您需要两个for循环。

额外的字符* #用于安全对抗/?(有助于快速眼动)。 或者行尾的插入号可以作为多行字符，甚至在rem之后。

然后从文件中读取rem参数输出，但要小心。 FOR /F应该在延迟展开关闭的情况下工作，否则带有"!"的内容将被销毁。 在删除param1中的额外字符后，您就得到了它。

要以安全的方式使用param1，请启用延迟扩展。

没有必要把事情复杂化。例如，它只是命令%1 %2参数，

@echo off

xcopy %1 %2 /D /E /C /Q /H /R /K /Y /Z

echo copied %1 to %2

pause

“pause”显示批处理文件所做的工作，并等待您按下ANY键。将其保存为Windows文件夹中的xx.bat。

要使用它，输入，例如:

xx c:\f\30\*.* f:\sites\30

这个批处理文件负责所有必要的参数，比如只复制文件、更新的文件等等。在Windows出现之前，我就开始使用它了。如果您喜欢在复制文件时查看文件名，可以省略Q参数。

要在命令行中引用一个set变量，你需要使用%a%，例如:

set a=100 
echo %a%  
rem output = 100 

注意:这适用于Windows 7 pro。

@ECHO OFF
:Loop
IF "%1"=="" GOTO Continue
SHIFT
GOTO Loop
:Continue

注意:如果“%1”==“”将导致问题，如果%1本身被括在引号中。

在这种情况下，使用IF[%1]==[]，或者仅在NT 4 (SP6)及以后版本中使用IF "%~1"==""。

FOR %%A IN (%*) DO (
    REM Now your batch file handles %%A instead of %1
    REM No need to use SHIFT anymore.
    ECHO %%A
)

这个循环遍历批处理参数(%*)，不管它们是否带引号，然后回显每个参数。

让我们保持简单。

下面是.cmd文件。

@echo off
rem this file is named echo_3params.cmd
echo %1
echo %2
echo %3
set v1=%1
set v2=%2
set v3=%3
echo v1 equals %v1%
echo v2 equals %v2%
echo v3 equals %v3%

下面是命令行中的3个调用。

C:\Users\joeco>echo_3params 1abc 2 def  3 ghi
1abc
2
def
v1 equals 1abc
v2 equals 2
v3 equals def

C:\Users\joeco>echo_3params 1abc "2 def"  "3 ghi"
1abc
"2 def"
"3 ghi"
v1 equals 1abc
v2 equals "2 def"
v3 equals "3 ghi"

C:\Users\joeco>echo_3params 1abc '2 def'  "3 ghi"
1abc
'2
def'
v1 equals 1abc
v2 equals '2
v3 equals def'

C:\Users\joeco>

我写了一个简单的read_params脚本，可以作为函数(或外部.bat)调用，并将所有变量放入当前环境中。它不会修改原始形参，因为函数是用原始形参的副本调用的。

例如，给定以下命令:

myscript.bat some -random=43 extra -greeting="hello world" fluff

Myscript.bat将能够在调用函数后使用变量:

call :read_params %*

echo %random%
echo %greeting%

函数如下:

:read_params
if not %1/==/ (
    if not "%__var%"=="" (
        if not "%__var:~0,1%"=="-" (
            endlocal
            goto read_params
        )
        endlocal & set %__var:~1%=%~1
    ) else (
        setlocal & set __var=%~1
    )
    shift
    goto read_params
)
exit /B

限制

不能加载无值的参数，例如-force。你可以使用-force=true，但我想不出一种方法来允许空值，而不知道提前知道一个参数列表，不会有一个值。

更新日志

2/18/2016 不再需要延迟扩展 现在通过查找- before形参来处理其他命令行参数。

最近有个朋友问我这个问题，所以我想在这里发布一下我如何在批处理文件中处理命令行参数。

正如您将看到的，这种技术有一些开销，但它使我的批处理文件非常容易理解和快速实现。以及支持以下结构:

>template.bat [-f] [--flag] [--namedvalue value] arg1 [arg2][arg3][...]

它的jist包含:init、:parse和:main函数。

示例使用

>template.bat /?
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.

USAGE:
test.bat [flags] "required argument" "optional argument"

/?, --help           shows this help
/v, --version        shows the version
/e, --verbose        shows detailed output
-f, --flag value     specifies a named parameter value

>template.bat          <- throws missing argument error
(same as /?, plus..)
****                                   ****
****    MISSING "REQUIRED ARGUMENT"    ****
****                                   ****

>template.bat -v
1.23

>template.bat --version
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.

>template.bat -e arg1
**** DEBUG IS ON
UnNamedArgument:    "arg1"
UnNamedOptionalArg: not provided
NamedFlag:          not provided

>template.bat --flag "my flag" arg1 arg2
UnNamedArgument:    "arg1"
UnNamedOptionalArg: "arg2"
NamedFlag:          "my flag"

>template.bat --verbose "argument #1" --flag "my flag" second
**** DEBUG IS ON
UnNamedArgument:    "argument #1"
UnNamedOptionalArg: "second"
NamedFlag:          "my flag"

template.bat

@::!/dos/rocks
@echo off
goto :init

:header
    echo %__NAME% v%__VERSION%
    echo This is a sample batch file template,
    echo providing command-line arguments and flags.
    echo.
    goto :eof

:usage
    echo USAGE:
    echo   %__BAT_NAME% [flags] "required argument" "optional argument" 
    echo.
    echo.  /?, --help           shows this help
    echo.  /v, --version        shows the version
    echo.  /e, --verbose        shows detailed output
    echo.  -f, --flag value     specifies a named parameter value
    goto :eof

:version
    if "%~1"=="full" call :header & goto :eof
    echo %__VERSION%
    goto :eof

:missing_argument
    call :header
    call :usage
    echo.
    echo ****                                   ****
    echo ****    MISSING "REQUIRED ARGUMENT"    ****
    echo ****                                   ****
    echo.
    goto :eof

:init
    set "__NAME=%~n0"
    set "__VERSION=1.23"
    set "__YEAR=2017"

    set "__BAT_FILE=%~0"
    set "__BAT_PATH=%~dp0"
    set "__BAT_NAME=%~nx0"

    set "OptHelp="
    set "OptVersion="
    set "OptVerbose="

    set "UnNamedArgument="
    set "UnNamedOptionalArg="
    set "NamedFlag="

:parse
    if "%~1"=="" goto :validate

    if /i "%~1"=="/?"         call :header & call :usage "%~2" & goto :end
    if /i "%~1"=="-?"         call :header & call :usage "%~2" & goto :end
    if /i "%~1"=="--help"     call :header & call :usage "%~2" & goto :end

    if /i "%~1"=="/v"         call :version      & goto :end
    if /i "%~1"=="-v"         call :version      & goto :end
    if /i "%~1"=="--version"  call :version full & goto :end

    if /i "%~1"=="/e"         set "OptVerbose=yes"  & shift & goto :parse
    if /i "%~1"=="-e"         set "OptVerbose=yes"  & shift & goto :parse
    if /i "%~1"=="--verbose"  set "OptVerbose=yes"  & shift & goto :parse

    if /i "%~1"=="--flag"     set "NamedFlag=%~2"   & shift & shift & goto :parse
    if /i "%~1"=="-f"         set "NamedFlag=%~2"   & shift & shift & goto :parse

    if not defined UnNamedArgument     set "UnNamedArgument=%~1"     & shift & goto :parse
    if not defined UnNamedOptionalArg  set "UnNamedOptionalArg=%~1"  & shift & goto :parse

    shift
    goto :parse

:validate
    if not defined UnNamedArgument call :missing_argument & goto :end

:main
    if defined OptVerbose (
        echo **** DEBUG IS ON
    )

    echo UnNamedArgument:    "%UnNamedArgument%"

    if defined UnNamedOptionalArg      echo UnNamedOptionalArg: "%UnNamedOptionalArg%"
    if not defined UnNamedOptionalArg  echo UnNamedOptionalArg: not provided

    if defined NamedFlag               echo NamedFlag:          "%NamedFlag%"
    if not defined NamedFlag           echo NamedFlag:          not provided

:end
    call :cleanup
    exit /B

:cleanup
    REM The cleanup function is only really necessary if you
    REM are _not_ using SETLOCAL.
    set "__NAME="
    set "__VERSION="
    set "__YEAR="

    set "__BAT_FILE="
    set "__BAT_PATH="
    set "__BAT_NAME="

    set "OptHelp="
    set "OptVersion="
    set "OptVerbose="

    set "UnNamedArgument="
    set "UnNamedArgument2="
    set "NamedFlag="

    goto :eof

受到@Jon在其他地方的回答的启发，我设计了一个更通用的算法来提取命名参数、可选值和开关。

假设我们想要实现一个实用程序foobar。它需要一个初始命令。它有一个可选参数——foo，它接受一个可选值(当然不能是另一个参数);如果缺少该值，则默认为default。它还有一个可选参数——bar，它接受一个必需的值。最后，它可以带一个标志——baz，不允许有任何值。哦，这些参数可以以任何顺序出现。

换句话说，它看起来像这样:

foobar <command> [--foo [<fooval>]] [--bar <barval>] [--baz]

这里有一个解决方案:

@ECHO OFF
SETLOCAL
REM FooBar parameter demo
REM By Garret Wilson

SET CMD=%~1

IF "%CMD%" == "" (
  GOTO usage
)
SET FOO=
SET DEFAULT_FOO=default
SET BAR=
SET BAZ=

SHIFT
:args
SET PARAM=%~1
SET ARG=%~2
IF "%PARAM%" == "--foo" (
  SHIFT
  IF NOT "%ARG%" == "" (
    IF NOT "%ARG:~0,2%" == "--" (
      SET FOO=%ARG%
      SHIFT
    ) ELSE (
      SET FOO=%DEFAULT_FOO%
    )
  ) ELSE (
    SET FOO=%DEFAULT_FOO%
  )
) ELSE IF "%PARAM%" == "--bar" (
  SHIFT
  IF NOT "%ARG%" == "" (
    SET BAR=%ARG%
    SHIFT
  ) ELSE (
    ECHO Missing bar value. 1>&2
    ECHO:
    GOTO usage
  )
) ELSE IF "%PARAM%" == "--baz" (
  SHIFT
  SET BAZ=true
) ELSE IF "%PARAM%" == "" (
  GOTO endargs
) ELSE (
  ECHO Unrecognized option %1. 1>&2
  ECHO:
  GOTO usage
)
GOTO args
:endargs

ECHO Command: %CMD%
IF NOT "%FOO%" == "" (
  ECHO Foo: %FOO%
)
IF NOT "%BAR%" == "" (
  ECHO Bar: %BAR%
)
IF "%BAZ%" == "true" (
  ECHO Baz
)

REM TODO do something with FOO, BAR, and/or BAZ
GOTO :eof

:usage
ECHO FooBar
ECHO Usage: foobar ^<command^> [--foo [^<fooval^>]] [--bar ^<barval^>] [--baz]
EXIT /B 1

使用SETLOCAL，这样变量就不会转义到调用环境。 不要忘记初始化变量SET FOO=等，以防有人在调用环境中定义了它们。 使用%~1删除引号。 使用IF "%ARG%" == ""，而不是IF [%ARG%] ==[]，因为[和]不会使用以空格结尾的值。 即使你在if块内SHIFT，当前的参数如%~1也不会被更新，因为它们是在解析if时确定的。您可以在IF块中使用%~1和%~2，但这将令人困惑，因为您有一个SHIFT。你可以把SHIFT放在块的末尾，但这可能会丢失和/或混淆人们。所以“捕获”块外的%~1和%~1似乎是最好的。 你不想用一个参数来代替另一个参数的可选值，所以你必须检查IF NOT "%ARG:~0,2%" == "——"。 当您使用其中一个参数时，请注意只使用SHIFT。 重复的代码SET FOO=%DEFAULT_FOO%是令人遗憾的，但另一种选择是在IF NOT "%ARG%" == ""块之外添加一个IF "%FOO%" == "" SET FOO=%DEFAULT_FOO%。然而，因为它仍然在IF "%PARAM%" == "——foo"块中，% foo %的值将在你进入块之前被计算和设置，所以你永远不会检测到——foo参数存在，而且% foo %的值缺失。 注意ECHO缺失条值。1>&2向stderr发送错误消息。 想在Windows批处理文件中使用空行?你必须使用ECHO:或其中一种变体。

简单的解决方法(即使问题已经很老了)

Test1.bat

echo off
echo "Batch started"
set arg1=%1
echo "arg1 is %arg1%"
echo on
pause

CallTest1.bat

call "C:\Temp\Test1.bat" pass123

输出

YourLocalPath>call "C:\Temp\test.bat" pass123

YourLocalPath>echo off
"Batch started"
"arg1 is pass123"

YourLocalPath>pause
Press any key to continue . . .

其中YourLocalPath是当前目录路径。

为了简单起见，将命令参数存储在变量中，并使用变量进行比较。

它不仅写起来简单，而且维护起来也很简单，所以如果后来其他人或你在很长一段时间后阅读了你的脚本，它将很容易理解和维护。

内联编写代码:参见其他答案。

对于使用循环获取所有参数并纯批处理:

注意事项:用于不带:?*&|<>

@echo off && setlocal EnableDelayedExpansion

 for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && (
     call set "_arg_[!_cnt!]=!_arg_!" && for /l %%l in (!_cnt! 1 !_cnt!
     )do echo/ The argument n:%%l is: !_arg_[%%l]!
 )

goto :eof 

你的代码已经准备好在需要的地方用参数号做一些事情，比如……

 @echo off && setlocal EnableDelayedExpansion

 for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && call set "_arg_[!_cnt!]=!_arg_!"
 
 fake-command /u !_arg_[1]! /p !_arg_[2]! > test-log.txt
 

批处理文件

set argument1=%1
set argument2=%2
echo %argument1%
echo %argument2%

%1和%2分别返回第一个和第二个参数值。

在命令行中，传递参数

Directory> batchFileName admin P@55w0rd 

输出将是

admin
P@55w0rd

成对的参数

如果你喜欢在键值对中传递参数，你可以使用这样的方法:

@echo off

setlocal enableDelayedExpansion

:::::  asigning arguments as a key-value pairs:::::::::::::
set counter=0
for %%# in (%*) do (    
    set /a counter=counter+1
    set /a even=counter%%2
    
    if !even! == 0 (
        echo setting !prev! to %%#
        set "!prev!=%%~#"
    )
    set "prev=%%~#"
)
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

:: showing the assignments
echo %one% %two% %three% %four% %five%

endlocal

举个例子:

c:>argumentsDemo.bat one 1 "two" 2 three 3 four 4 "five" 5
1 2 3 4 5

预定义的变量

您还可以提前设置一些环境变量。这可以通过在控制台或在我的电脑上设置来完成:

@echo off

if defined variable1 (
    echo %variable1%
)

if defined variable2 (
    echo %variable2%
)

像这样称呼它:

c:\>set variable1=1

c:\>set variable2=2

c:\>argumentsTest.bat
1
2

包含列出值的文件

您还可以指向预先设置所需值的文件。 如果这是脚本:

@echo off

setlocal
::::::::::
set "VALUES_FILE=E:\scripts\values.txt"
:::::::::::


for /f "usebackq eol=: tokens=* delims=" %%# in ("%VALUES_FILE%") do set "%%#"

echo %key1% %key2% %some_other_key%

endlocal

values文件是这样的:

:::: use EOL=: in the FOR loop to use it as a comment

key1=value1

key2=value2

:::: do not left spaces arround the =
:::: or at the begining of the line

some_other_key=something else

and_one_more=more

调用它的输出将是:

Value1 value2别的东西

当然，您可以结合所有方法。检查参数语法，shift

每个人的回答都很复杂，但实际上很简单。%1 %2 %3等是解析到文件的参数。%1是参数1，%2是参数2，以此类推。

所以，如果我有一个bat脚本包含这个:

@echo off
echo %1

当我运行批处理脚本时，我输入这个:

C:> script.bat Hello

脚本将简单地输出:

Hello

这对于脚本中的某些变量非常有用，比如名字和年龄。如果我有一个这样的脚本:

@echo off
echo Your name is: %1
echo Your age is: %2

当我输入这个:

C:> script.bat Oliver 1000

我得到这样的输出:

Your name is: Oliver
Your age is: 1000

如果你担心安全/密码盗窃(导致你设计这个解决方案,需要登录凭证在执行而不是静态的硬编码不需要数据库),然后您可以存储api或一半密码解密的代码或程序文件解密密钥,所以在运行时,用户将在控制台输入用户名/密码散列/解密之前传递给程序代码执行通过设置/ p,如果你查看在运行时用户输入凭据。

如果您正在运行一个脚本，使用不同的用户/密码运行程序，那么命令行参数将适合您。

如果您正在制作一个测试文件来查看不同登录的输出/效果，那么您可以将所有登录存储在一个加密文件中，作为参数传递给test。Cmd，除非你想坐在命令行并输入所有的登录，直到完成。

可以提供的参数数量限制为命令行上的字符总数。为了克服这一限制，上一段技巧是一种变通方法，不会有暴露用户密码的风险。