FOR %%A IN (%*) DO (
    REM Now your batch file handles %%A instead of %1
    REM No need to use SHIFT anymore.
    ECHO %%A
)

这个循环遍历批处理参数(%*)，不管它们是否带引号，然后回显每个参数。

我是这样做的:

@fake-command /u %1 /p %2

下面是命令的样子:

test.cmd admin P@55w0rd > test-log.txt

%1应用于第一个参数，%2(这是棘手的部分)应用于第二个参数。您最多可以通过这种方式传递9个参数。

如果你想智能地处理缺失的参数，你可以这样做:

IF %1.==. GOTO No1
IF %2.==. GOTO No2
... do stuff...
GOTO End1

:No1
  ECHO No param 1
GOTO End1
:No2
  ECHO No param 2
GOTO End1

:End1

每个人的回答都很复杂，但实际上很简单。%1 %2 %3等是解析到文件的参数。%1是参数1，%2是参数2，以此类推。

所以，如果我有一个bat脚本包含这个:

@echo off
echo %1

当我运行批处理脚本时，我输入这个:

C:> script.bat Hello

脚本将简单地输出:

Hello

这对于脚本中的某些变量非常有用，比如名字和年龄。如果我有一个这样的脚本:

@echo off
echo Your name is: %1
echo Your age is: %2

当我输入这个:

C:> script.bat Oliver 1000

我得到这样的输出:

Your name is: Oliver
Your age is: 1000

我写了一个简单的read_params脚本，可以作为函数(或外部.bat)调用，并将所有变量放入当前环境中。它不会修改原始形参，因为函数是用原始形参的副本调用的。

例如，给定以下命令:

myscript.bat some -random=43 extra -greeting="hello world" fluff

Myscript.bat将能够在调用函数后使用变量:

call :read_params %*

echo %random%
echo %greeting%

函数如下:

:read_params
if not %1/==/ (
    if not "%__var%"=="" (
        if not "%__var:~0,1%"=="-" (
            endlocal
            goto read_params
        )
        endlocal & set %__var:~1%=%~1
    ) else (
        setlocal & set __var=%~1
    )
    shift
    goto read_params
)
exit /B

限制

不能加载无值的参数，例如-force。你可以使用-force=true，但我想不出一种方法来允许空值，而不知道提前知道一个参数列表，不会有一个值。

更新日志

2/18/2016 不再需要延迟扩展 现在通过查找- before形参来处理其他命令行参数。

受到@Jon在其他地方的回答的启发，我设计了一个更通用的算法来提取命名参数、可选值和开关。

假设我们想要实现一个实用程序foobar。它需要一个初始命令。它有一个可选参数——foo，它接受一个可选值(当然不能是另一个参数);如果缺少该值，则默认为default。它还有一个可选参数——bar，它接受一个必需的值。最后，它可以带一个标志——baz，不允许有任何值。哦，这些参数可以以任何顺序出现。

换句话说，它看起来像这样:

foobar <command> [--foo [<fooval>]] [--bar <barval>] [--baz]

这里有一个解决方案:

@ECHO OFF
SETLOCAL
REM FooBar parameter demo
REM By Garret Wilson

SET CMD=%~1

IF "%CMD%" == "" (
  GOTO usage
)
SET FOO=
SET DEFAULT_FOO=default
SET BAR=
SET BAZ=

SHIFT
:args
SET PARAM=%~1
SET ARG=%~2
IF "%PARAM%" == "--foo" (
  SHIFT
  IF NOT "%ARG%" == "" (
    IF NOT "%ARG:~0,2%" == "--" (
      SET FOO=%ARG%
      SHIFT
    ) ELSE (
      SET FOO=%DEFAULT_FOO%
    )
  ) ELSE (
    SET FOO=%DEFAULT_FOO%
  )
) ELSE IF "%PARAM%" == "--bar" (
  SHIFT
  IF NOT "%ARG%" == "" (
    SET BAR=%ARG%
    SHIFT
  ) ELSE (
    ECHO Missing bar value. 1>&2
    ECHO:
    GOTO usage
  )
) ELSE IF "%PARAM%" == "--baz" (
  SHIFT
  SET BAZ=true
) ELSE IF "%PARAM%" == "" (
  GOTO endargs
) ELSE (
  ECHO Unrecognized option %1. 1>&2
  ECHO:
  GOTO usage
)
GOTO args
:endargs

ECHO Command: %CMD%
IF NOT "%FOO%" == "" (
  ECHO Foo: %FOO%
)
IF NOT "%BAR%" == "" (
  ECHO Bar: %BAR%
)
IF "%BAZ%" == "true" (
  ECHO Baz
)

REM TODO do something with FOO, BAR, and/or BAZ
GOTO :eof

:usage
ECHO FooBar
ECHO Usage: foobar ^<command^> [--foo [^<fooval^>]] [--bar ^<barval^>] [--baz]
EXIT /B 1

使用SETLOCAL，这样变量就不会转义到调用环境。 不要忘记初始化变量SET FOO=等，以防有人在调用环境中定义了它们。 使用%~1删除引号。 使用IF "%ARG%" == ""，而不是IF [%ARG%] ==[]，因为[和]不会使用以空格结尾的值。 即使你在if块内SHIFT，当前的参数如%~1也不会被更新，因为它们是在解析if时确定的。您可以在IF块中使用%~1和%~2，但这将令人困惑，因为您有一个SHIFT。你可以把SHIFT放在块的末尾，但这可能会丢失和/或混淆人们。所以“捕获”块外的%~1和%~1似乎是最好的。 你不想用一个参数来代替另一个参数的可选值，所以你必须检查IF NOT "%ARG:~0,2%" == "——"。 当您使用其中一个参数时，请注意只使用SHIFT。 重复的代码SET FOO=%DEFAULT_FOO%是令人遗憾的，但另一种选择是在IF NOT "%ARG%" == ""块之外添加一个IF "%FOO%" == "" SET FOO=%DEFAULT_FOO%。然而，因为它仍然在IF "%PARAM%" == "——foo"块中，% foo %的值将在你进入块之前被计算和设置，所以你永远不会检测到——foo参数存在，而且% foo %的值缺失。 注意ECHO缺失条值。1>&2向stderr发送错误消息。 想在Windows批处理文件中使用空行?你必须使用ECHO:或其中一种变体。