这可能为你工作(GNU sed):

sed -r '1{x;s/^/:abbc:bcab/;x};G;s/^/\n/;:a;/\n\n/{P;d};s/\n(ab|bc)(.*\n.*:(\1)([^:]*))/\4\n\2/;ta;s/\n(.)/\1\n/;ta' file

它使用一个查找表，该表准备好并保存在保留空间(HS)中，然后附加到每一行。一个唯一的标记(在本例中是\n)被前置在行开始之前，并用作在整个行长度上进行搜索的方法。一旦标记到达行尾，该过程就完成了，并打印出查找表，标记被丢弃。

注意:查找表在一开始就准备好了，并且选择了第二个唯一标记(在本例中为:)，以避免与替换字符串冲突。

以下是一些评论:

sed -r '
  # initialize hold with :abbc:bcab
  1 {
    x
    s/^/:abbc:bcab/
    x
  }

  G        # append hold to patt (after a \n)

  s/^/\n/  # prepend a \n

  :a

  /\n\n/ {
    P      # print patt up to first \n
    d      # delete patt & start next cycle
  }

  s/\n(ab|bc)(.*\n.*:(\1)([^:]*))/\4\n\2/
  ta       # goto a if sub occurred

  s/\n(.)/\1\n/  # move one char past the first \n
  ta       # goto a if sub occurred
'

这个表格是这样的:

   **   **   replacement
:abbc:bcab
 **   **     pattern

Sed是一个流编辑器。它贪婪地搜索和替换。实现您所要求的唯一方法是使用中间替换模式，并在最后将其更改回来。

Echo 'abcd' | sed -e /ab/xy/;s/cd/ab/;s/xy/cd/'

也许是这样的:

sed 's/ab/~~/g; s/bc/ab/g; s/~~/bc/g'

将~替换为一个您知道不会出现在字符串中的字符。

这是一个基于oogas sed的awk

echo 'abbc' | awk '{gsub(/ab/,"xy");gsub(/bc/,"ab");gsub(/xy/,"bc")}1'
bcab

Tcl有一个内置的功能

$ tclsh
% string map {ab bc bc ab} abbc
bcab

它的工作原理是每次遍历字符串的一个字符，从当前位置开始进行字符串比较。

在perl中:

perl -E '
    sub string_map {
        my ($str, %map) = @_;
        my $i = 0;
        while ($i < length $str) {
          KEYS:
            for my $key (keys %map) {
                if (substr($str, $i, length $key) eq $key) {
                    substr($str, $i, length $key) = $map{$key};
                    $i += length($map{$key}) - 1;
                    last KEYS;
                }
            }
            $i++;
        }
        return $str;
    }
    say string_map("abbc", "ab"=>"bc", "bc"=>"ab");
'

bcab

对于单个模式的出现，可能有一个更简单的方法，您可以尝试如下: Echo 'abbc' | sed 's/ab/bc/; 's/ bc/ab/2'

我的输出:

 ~# echo 'abbc' | sed 's/ab/bc/;s/bc/ab/2'
 bcab

对于pattern的多次出现:

sed 's/\(ab\)\(bc\)/\2\1/g'

例子

~# cat try.txt
abbc abbc abbc
bcab abbc bcab
abbc abbc bcab

~# sed 's/\(ab\)\(bc\)/\2\1/g' try.txt
bcab bcab bcab
bcab bcab bcab
bcab bcab bcab

希望这能有所帮助!!