对于InnoDB，下面的方法似乎是可行的:创建新的空数据库，然后依次将每个表重命名为新的数据库:

RENAME TABLE old_db.table TO new_db.table;

之后，您将需要调整权限。

对于在shell中编写脚本，您可以使用以下任何一种:

mysql -u username -ppassword old_db -sNe 'show tables' | while read table; \ 
    do mysql -u username -ppassword -sNe "rename table old_db.$table to new_db.$table"; done

OR

for table in `mysql -u root -ppassword -s -N -e "use old_db;show tables from old_db;"`; do mysql -u root -ppassword -s -N -e "use old_db;rename table old_db.$table to new_db.$table;"; done;

注:

选项-p和密码之间没有空格。如果您的数据库没有密码，请删除-u username -ppassword部分。 如果某个表有触发器，则不能使用上述方法将其移动到另一个数据库(将导致trigger in wrong schema错误)。如果是这种情况，使用传统的方法克隆一个数据库，然后删除旧的: Mysqldump old_db | mysql new_db 如果你有存储过程，你可以在之后复制它们: mysqldump -R old_db | mysql的new_db

这是我写的一个批处理文件，从命令行自动化，但它适用于Windows/MS-DOS。

语法:rename_mysqldb database newdatabase -u [user] -p[password]

:: ***************************************************************************
:: FILE: RENAME_MYSQLDB.BAT
:: ***************************************************************************
:: DESCRIPTION
:: This is a Windows /MS-DOS batch file that automates renaming a MySQL database 
:: by using MySQLDump, MySQLAdmin, and MySQL to perform the required tasks.
:: The MySQL\bin folder needs to be in your environment path or the working directory.
::
:: WARNING: The script will delete the original database, but only if it successfully
:: created the new copy. However, read the disclaimer below before using.
::
:: DISCLAIMER
:: This script is provided without any express or implied warranties whatsoever.
:: The user must assume the risk of using the script.
::
:: You are free to use, modify, and distribute this script without exception.
:: ***************************************************************************

:INITIALIZE
@ECHO OFF
IF [%2]==[] GOTO HELP
IF [%3]==[] (SET RDB_ARGS=--user=root) ELSE (SET RDB_ARGS=%3 %4 %5 %6 %7 %8 %9)
SET RDB_OLDDB=%1
SET RDB_NEWDB=%2
SET RDB_DUMPFILE=%RDB_OLDDB%_dump.sql
GOTO START

:START
SET RDB_STEP=1
ECHO Dumping "%RDB_OLDDB%"...
mysqldump %RDB_ARGS% %RDB_OLDDB% > %RDB_DUMPFILE%
IF %ERRORLEVEL% NEQ 0 GOTO ERROR_ABORT
SET RDB_STEP=2
ECHO Creating database "%RDB_NEWDB%"...
mysqladmin %RDB_ARGS% create %RDB_NEWDB%
IF %ERRORLEVEL% NEQ 0 GOTO ERROR_ABORT
SET RDB_STEP=3
ECHO Loading dump into "%RDB_NEWDB%"...
mysql %RDB_ARGS% %RDB_NEWDB% < %RDB_DUMPFILE%
IF %ERRORLEVEL% NEQ 0 GOTO ERROR_ABORT
SET RDB_STEP=4
ECHO Dropping database "%RDB_OLDDB%"...
mysqladmin %RDB_ARGS% drop %RDB_OLDDB% --force
IF %ERRORLEVEL% NEQ 0 GOTO ERROR_ABORT
SET RDB_STEP=5
ECHO Deleting dump...
DEL %RDB_DUMPFILE%
IF %ERRORLEVEL% NEQ 0 GOTO ERROR_ABORT
ECHO Renamed database "%RDB_OLDDB%" to "%RDB_NEWDB%".
GOTO END

:ERROR_ABORT
IF %RDB_STEP% GEQ 3 mysqladmin %RDB_ARGS% drop %NEWDB% --force
IF %RDB_STEP% GEQ 1 IF EXIST %RDB_DUMPFILE% DEL %RDB_DUMPFILE%
ECHO Unable to rename database "%RDB_OLDDB%" to "%RDB_NEWDB%".
GOTO END

:HELP
ECHO Renames a MySQL database.
ECHO Usage: %0 database new_database [OPTIONS]
ECHO Options: Any valid options shared by MySQL, MySQLAdmin and MySQLDump.
ECHO          --user=root is used if no options are specified.
GOTO END    

:END
SET RDB_OLDDB=
SET RDB_NEWDB=
SET RDB_ARGS=
SET RDB_DUMP=
SET RDB_STEP=

这适用于所有数据库，通过使用maatkit mysql工具包重命名每个表

使用mk-find打印并重命名每个表。手册页有更多选项和示例

mk-find --dblike OLD_DATABASE --print --exec "RENAME TABLE %D.%N TO NEW_DATABASE.%N"

如果您安装了maatkit(这非常简单)，那么这是最简单的方法。

如果你正在使用phpMyAdmin，一旦你选择了你想要重命名的数据库，你可以去“操作”选项卡。然后转到最后一节“将数据库复制到”(或类似的内容)，给出一个名称，并选择下面的选项。在这种情况下，我猜你必须选择“结构和数据”和“在复制之前创建数据库”复选框，最后，按下该部分中的“go”按钮。

顺便说一下，我在西班牙语中使用phpMyAdmin，所以我不确定英语部分的名称是什么。

为了方便起见，下面是一个小shell脚本，必须使用两个参数执行:db-name和new db-name。

如果您不使用主目录中的.my.cnf文件，则可能需要在mysql行中添加登录参数。请在执行此脚本之前进行备份。

#!/usr/bin/env bash

mysql -e "CREATE DATABASE $2 DEFAULT CHARACTER SET utf8 COLLATE utf8_general_ci;"
for i in $(mysql -Ns $1 -e "show tables");do
    echo "$1.$i -> $2.$i"
    mysql -e "rename TABLE $1.$i to $2.$i"
done
mysql -e "DROP DATABASE $1"

对于InnoDB，下面的方法似乎是可行的:创建新的空数据库，然后依次将每个表重命名为新的数据库:

RENAME TABLE old_db.table TO new_db.table;

之后，您将需要调整权限。

对于在shell中编写脚本，您可以使用以下任何一种:

mysql -u username -ppassword old_db -sNe 'show tables' | while read table; \ 
    do mysql -u username -ppassword -sNe "rename table old_db.$table to new_db.$table"; done

OR

for table in `mysql -u root -ppassword -s -N -e "use old_db;show tables from old_db;"`; do mysql -u root -ppassword -s -N -e "use old_db;rename table old_db.$table to new_db.$table;"; done;

注:

选项-p和密码之间没有空格。如果您的数据库没有密码，请删除-u username -ppassword部分。 如果某个表有触发器，则不能使用上述方法将其移动到另一个数据库(将导致trigger in wrong schema错误)。如果是这种情况，使用传统的方法克隆一个数据库，然后删除旧的: Mysqldump old_db | mysql new_db 如果你有存储过程，你可以在之后复制它们: mysqldump -R old_db | mysql的new_db