如何在Windows命令行中以合适的格式获取当前日期/时间，以便在文件/文件夹名称中使用?

更新:现在是2016年，我将使用PowerShell，除非有一个真正令人信服的向后兼容的原因，特别是因为使用日期的区域设置问题。参见@npocmaka的https://stackoverflow.com/a/19799236/8479

什么是Windows命令行语句(s)，我可以使用以我可以放入文件名的格式获取当前日期时间?

我想要一个.bat文件，它将一个目录压缩成一个归档文件，其中当前日期和时间作为名称的一部分，例如Code_2008-10-14_2257.zip。有什么简单的方法可以做到这一点，独立于机器的区域设置吗?

我真的不介意日期格式，理想情况下它是yyyy-mm-dd，但任何简单的都可以。

到目前为止，我已经得到了这个，在我的机器上给我Tue_10_14_2008_230050_91:

rem Get the datetime in a format that can go in a filename.
set _my_datetime=%date%_%time%
set _my_datetime=%_my_datetime: =_%
set _my_datetime=%_my_datetime::=%
set _my_datetime=%_my_datetime:/=_%
set _my_datetime=%_my_datetime:.=_%

rem Now use the timestamp by in a new ZIP file name.
"d:\Program Files\7-Zip\7z.exe" a -r Code_%_my_datetime%.zip Code

我可以接受这个，但它似乎有点笨重。理想情况下，它应该更简短，并具有前面提到的格式。

我用的是Windows Server 2003和Windows XP Professional。我不想安装额外的实用程序来实现这一点(尽管我知道有一些工具可以很好地格式化日期)。

当前回答

简单回答:

 :: Start - Run , type:
 cmd /c "powershell get-date -format ^"{yyyy-MM-dd HH:mm:ss}^"|clip"

 :: click into target media, Ctrl + V to paste the result

长回答

    @echo off
    :: START USAGE  ==================================================================
    ::SET THE NICETIME 
    :: SET NICETIME=BOO
    :: CALL GetNiceTime.cmd 

    :: ECHO NICETIME IS %NICETIME%

    :: echo nice time is %NICETIME%
    :: END USAGE  ==================================================================

    echo set hhmmsss
    :: this is Regional settings dependant so tweak this according your current settings
    for /f "tokens=1-3 delims=:" %%a in ('echo %time%') do set hhmmsss=%%a%%b%%c 
    ::DEBUG ECHO hhmmsss IS %hhmmsss%
    ::DEBUG PAUSE
    echo %yyyymmdd%
        :: this is Regional settings dependant so tweak this according your current settings
    for /f "tokens=1-3 delims=." %%D in ('echo %DATE%') do set  yyyymmdd=%%F%%E%%D
    ::DEBUG ECHO yyyymmdd IS %yyyymmdd%
    ::DEBUG PAUSE


    set NICETIME=%yyyymmdd%_%hhmmsss%
    ::DEBUG echo THE NICETIME IS %NICETIME%

    ::DEBUG PAUSE

2010-05-18 06:03:16

其他回答

我使用date.exe，并将其重命名为date_unxutils.exe以避免冲突。把它放在批处理脚本旁边的bin文件夹中。

Code

:: Add binaries to temp path
IF EXIST bin SET PATH=%PATH%;bin

:: Create UTC Timestamp string in a custom format
:: Example: 20210128172058
set timestamp_command='date_unxutils.exe -u +"%%Y%%m%%d%%H%%M%%S"'
FOR /F %%i IN (%timestamp_command%) DO set timestamp=%%i
echo %timestamp%

Download UnxUtils

链接。

参考文献

我建立在这个很棒的答案上。

2021-01-28 19:17:13

不幸的是，这并不是不受区域设置的影响，但它确实是你想要的。

set hour=%time:~0,2%
if "%time:~0,1%"==" " set hour=0%time:~1,1%
set _my_datetime=%date:~10,4%-%date:~4,2%-%date:~7,2%_%hour%%time:~3,2%

你能在维基百科上找到的东西真是太神奇了。

2008-10-14 22:43:39

"d:\Program Files\7-Zip\7z.exe" a -r code_%date:~10,4%-%date:~4,2%-%date:~7,2%.zip

2009-12-04 19:44:01

一个基于wmic的函数:

:Now  -- Gets the current date and time into separate variables
::    %~1: [out] Year
::    %~2: [out] Month
::    %~3: [out] Day
::    %~4: [out] Hour
::    %~5: [out] Minute
::    %~6: [out] Second
  setlocal
  for /f %%t in ('wmic os get LocalDateTime ^| findstr /b [0-9]') do set T=%%t
  endlocal & (
    if "%~1" neq "" set %~1=%T:~0,4%
    if "%~2" neq "" set %~2=%T:~4,2%
    if "%~3" neq "" set %~3=%T:~6,2%
    if "%~4" neq "" set %~4=%T:~8,2%
    if "%~5" neq "" set %~5=%T:~10,2%
    if "%~6" neq "" set %~6=%T:~12,2%
  )
goto:eof

优点:独立于地区。缺点:只有系统管理员才能运行wmic.exe。

用法:

call:Now Y M D H N S
echo %Y%-%M%-%D% %H%:%N%:%S%

它像这样回显一个字符串:

2014-01-22 12:51:53

注意，函数形参是外形参——也就是说，您必须提供变量名而不是值。

所有参数都是可选的，因此调用:Now Y M是一个有效的调用，如果您只想获得年和月。

2014-01-22 11:59:17

http://sourceforge.net/projects/unxutils/files/

查看ZIP文件中的“Date.exe”，并将其重命名为“DateFormat.exe”(以避免冲突)。

把它放在你的Windows system32文件夹中。

它有很多“日期输出”选项。

如需帮助，请使用DateFormat.exe——h

我不确定如何将其输出放入环境变量中…使用设置。

2010-10-31 04:45:36

如何在Windows命令行中以合适的格式获取当前日期/时间，以便在文件/文件夹名称中使用?

推荐文章

最新文章

标签