一行（bash）。对我来说最短、最简单。

pip install -U $(pip freeze | cut -d = -f 1)

解释：

pip冻结返回每个包的package_name==版本cut-d=-f 1表示“对于每一行，返回第一行的字段，其中字段由=分隔”$（cmd）返回命令cmd的结果。因此，在这里，cmd将返回包名列表，pip install-U将对其进行升级。

在Windows或Linux上更新Python包

1-将已安装软件包的列表输出到需求文件（requirements.txt）中：

pip freeze > requirements.txt

2-编辑requirements.txt，并将所有“==”替换为“>=”。在编辑器中使用“全部替换”命令。

3-升级所有过时的软件包

pip install -r requirements.txt --upgrade

资料来源：https://www.activestate.com/resources/quick-reads/how-to-update-all-python-packages/

从…起https://github.com/cakebread/yolk:

$ pip install -U `yolk -U | awk '{print $1}' | uniq`

然而，你需要先得到蛋黄：

$ sudo pip install -U yolk

这似乎对我有用。。。

pip install -U $(pip list --outdated | awk '{printf $1" "}')

之后，我使用带有空格的printf来正确分隔包名。

以下是通过pip更新所有Python 3包（在激活的virtualenv中）的代码：

import pkg_resources
from subprocess import call

for dist in pkg_resources.working_set:
    call("python3 -m pip install --upgrade " + dist.project_name, shell=True)

以下Windows cmd代码段执行以下操作：

将pip升级到最新版本。升级所有过时的软件包。对于正在升级的每个包，检查requirements.txt中的任何版本说明符。

@echo off
Setlocal EnableDelayedExpansion
rem https://stackoverflow.com/questions/2720014/

echo Upgrading pip...
python -m pip install --upgrade pip
echo.

echo Upgrading packages...
set upgrade_count=0
pip list --outdated > pip-upgrade-outdated.txt
for /F "skip=2 tokens=1,3 delims= " %%i in (pip-upgrade-outdated.txt) do (
    echo ^>%%i
    set package=%%i
    set latest=%%j
    set requirements=!package!

    rem for each outdated package check for any version requirements:
    set dotest=1
    for /F %%r in (.\python\requirements.txt) do (
        if !dotest!==1 (
            call :substr "%%r" !package! _substr
            rem check if a given line refers to a package we are about to upgrade:
            if "%%r" NEQ !_substr! (
                rem check if the line contains more than just a package name:
                if "%%r" NEQ "!package!" (
                    rem set requirements to the contents of the line:
                    echo requirements: %%r, latest: !latest!
                    set requirements=%%r
                )
                rem stop testing after the first instance found,
                rem prevents from mistakenly matching "py" with "pylint", "numpy" etc.
                rem requirements.txt must be structured with shorter names going first
                set dotest=0
            )
        )
    )
    rem pip install !requirements!
    pip install --upgrade !requirements!
    set /a "upgrade_count+=1"
    echo.
)

if !upgrade_count!==0 (
    echo All packages are up to date.
) else (
    type pip-upgrade-outdated.txt
)

if "%1" neq "-silent" (
    echo.
    set /p temp="> Press Enter to exit..."
)
exit /b


:substr
rem string substition done in a separate subroutine -
rem allows expand both variables in the substring syntax.
rem replaces str_search with an empty string.
rem returns the result in the 3rd parameter, passed by reference from the caller.
set str_source=%1
set str_search=%2
set str_result=!str_source:%str_search%=!
set "%~3=!str_result!"
rem echo !str_source!, !str_search!, !str_result!
exit /b