我真的是批处理文件的新手，这是我的代码!!(我不知道为什么，但我不能结合日期/t和时间/t在一起，我不能直接使用%date%和%time%没有变量…)

@ECHO OFF
set ldt=%date% %time%
echo %ldt%>> logs.txt
EXIT

它在某种程度上是从其他人那里重用的(问题是获得一个格式化的时间作为文件名)。

@ECHO OFF
: Sets the proper date and time stamp with 24Hr Time for log file naming
: convention ('YYYYMMDD_HHMMSS')

: Scrapes the characters out of their expected permissions in the date/time
: environment variables.

: Expects a date format of '____MM_DD_YYYY'
: Expects a time format of 'HH:MM:SS' or ' H:MM:SS'

SET HOUR=%time:~0,2%
SET dtStamp9=%date:~-4%%date:~4,2%%date:~7,2%_0%time:~1,1%%time:~3,2%%time:~6,2% 
SET dtStamp24=%date:~-4%%date:~4,2%%date:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%

if "%HOUR:~0,1%" == " " (SET dtStamp=%dtStamp9%) else (SET dtStamp=%dtStamp24%)

ECHO %dtStamp%

PAUSE

for /f "tokens=1-4 delims=/ " %%I in ("%DATE%") do set curdate=%%K_%%J_%%I
for /f "tokens=1-4 delims=:," %%I in ("%TIME: =0%") do set curtime=%%I_%%J_%%K
echo %curdate%__%curtime%

如果您的系统使用另一个替换delims符号(用于切片到%%I，%%J…) 如果您的系统使用另一个D/M/Y订单，也可以编辑curdate

我尝试了公认的答案，效果很好。不幸的是，美国时间格式似乎是H:MM:SS.CS，前面缺少0导致上午10点之前的解析问题。为了克服这个障碍，并允许解析大多数世界时间格式，我提出了这个简单的例程，它似乎工作得相当好。

:ParseTime
rem The format of %%TIME%% is H:MM:SS.CS or (HH:MM:SS,CS) for example 0:01:23.45 or 23:59:59,99
FOR /F "tokens=1,2,3,4 delims=:.," %%a IN ("%1") DO SET /A "%2=(%%a * 360000) + (%%b * 6000) + (%%c * 100) + %%d"
GOTO :EOF

这个例程的好处是将时间字符串作为第一个参数传入，将希望包含时间(以厘秒为单位)的环境变量名称作为第二个参数传入。例如:

CALL :ParseTime %START_TIME% START_CS
CALL :ParseTime %TIME% END_CS
SET /A DURATION=%END_CS% - %START_CS%

克里斯(* *)

如前所述，只有在您知道当前用户使用的格式(例如，MM/dd/yy或dd-MM-yyyy，仅举两个例子)时，解析日期和时间才有用。这是可以确定的，但是当您完成所有的强调和解析时，您仍然会遇到使用了意想不到的格式的情况，需要进行更多的调整。

您还可以使用一些外部程序，它们将以您喜欢的格式返回日期段，但这样做的缺点是需要将实用程序与脚本/批处理一起分发。

也有批处理技巧使用CMOS时钟在一个相当原始的方式，但这是太接近裸线对大多数人来说，也不总是首选的地方来检索日期/时间。

下面是避免上述问题的解决方案。是的，它引入了一些其他问题，但就我的目的而言，我发现这是在现代Windows系统的.bat文件中创建日期戳的最简单、最清晰、最可移植的解决方案。这只是一个示例，但我认为您将看到如何修改其他日期和/或时间格式等。

reg copy "HKCU\Control Panel\International" "HKCU\Control Panel\International-Temp" /f
reg add "HKCU\Control Panel\International" /v sShortDate /d "yyMMdd" /f
@REM reg query "HKCU\Control Panel\International" /v sShortDate
set LogDate=%date%
reg copy "HKCU\Control Panel\International-Temp" "HKCU\Control Panel\International" /f

因此，%DATE%的问题在于它依赖于区域设置。所以之前的大部分答案对我来说都不适用。如果你对确切的格式不挑剔，只是想要一个时间戳来区分文件，你可以这样做:

set _date=%DATE%-%TIME%
set _date=%_date:/=-%
set _date=%_date: =-%
set _date=%_date::=-%
set _date=%_date:.=-%
echo %_date%

这应该适用于大多数地区。如果它没有添加另一行，则设置_date=%_date:<offending_char>=-%以删除有问题的字符。例如:一个与文件名不兼容的字符或文件名中不希望出现的字符。

请注意，这并不符合问题所规定的确切标准。