尽管使用起来很方便，但转换为哈希的解决方案似乎消耗了相当多的性能，这对我来说是个问题。

#!/usr/bin/perl
use Benchmark;
my @list;
for (1..10_000) {
    push @list, $_;
}

timethese(10000, {
  'grep'    => sub {
            if ( grep(/^5000$/o, @list) ) {
                # code
            }
        },
  'hash'    => sub {
            my %params = map { $_ => 1 } @list;
            if ( exists($params{5000}) ) {
                # code
            }
        },
});

基准测试输出:

Benchmark: timing 10000 iterations of grep, hash...
          grep:  8 wallclock secs ( 7.95 usr +  0.00 sys =  7.95 CPU) @ 1257.86/s (n=10000)
          hash: 50 wallclock secs (49.68 usr +  0.01 sys = 49.69 CPU) @ 201.25/s (n=10000)

最佳通用-特别是短数组(1000项或更少)和不确定哪种优化最适合他们的需求的编码员。

# $value can be any regex. be safe
if ( grep( /^$value$/, @array ) ) {
  print "found it";
}

前面提到过，即使数组中的第一个值匹配，grep也会遍历所有值。这是事实，但是grep在大多数情况下仍然非常快。如果你谈论的是短数组(少于1000项)，那么大多数算法无论如何都会非常快。如果您谈论的是非常长的数组(1,000,000个项)，无论项是数组中的第一个、中间还是最后一个，grep都是可以接受的。

更长的数组优化案例:

如果你的数组是排序的，使用“二分搜索”。

如果重复搜索同一数组多次，则先将其复制到哈希中，然后再检查哈希。如果内存是一个问题，那么将每个项从数组移动到散列中。内存效率更高，但会破坏原始数组。

如果在数组中重复搜索相同的值，则惰性地构建缓存。(在搜索每个项时，首先检查搜索结果是否存储在持久散列中。如果在哈希中没有找到搜索结果，则搜索数组并将结果放入持久哈希中，以便下次在哈希中找到它并跳过搜索)。

注意:这些优化只会在处理长数组时更快。不要过度优化。

你可以在Perl 5.10中使用smartmatch特性，如下所示:

对于文字值查找，执行下面的操作即可。

if ( "value" ~~ @array ) 

对于标量查找，执行以下操作将与上述工作一样。

if ($val ~~ @array)

对于内联数组做下面，将工作如上。

if ( $var ~~ ['bar', 'value', 'foo'] ) 

在Perl 5.18中，smartmatch被标记为实验性的，因此你需要通过在你的脚本/模块中添加以下内容来打开实验性的pragma来关闭警告:

use experimental 'smartmatch';

或者，如果你想避免使用smartmatch，那么就像Aaron说的那样使用:

if ( grep( /^$value$/, @array ) ) {
  #TODO:
}

@eakssjo的基准测试被打破了——测量在循环中创建哈希和在循环中创建正则表达式。修正版本(加上我已经添加了List::Util::first和List::MoreUtils::any):

use List::Util qw(first);
use List::MoreUtils qw(any);
use Benchmark;

my @list = ( 1..10_000 );
my $hit = 5_000;
my $hit_regex = qr/^$hit$/; # precompute regex
my %params;
$params{$_} = 1 for @list;  # precompute hash
timethese(
    100_000, {
        'any' => sub {
            die unless ( any { $hit_regex } @list );
        },
        'first' => sub {
            die unless ( first { $hit_regex } @list );
        },
        'grep' => sub {
            die unless ( grep { $hit_regex } @list );
        },
        'hash' => sub {
            die unless ( $params{$hit} );
        },
    });

结果(100_000次迭代，比@eakssjo的答案多十倍):

Benchmark: timing 100000 iterations of any, first, grep, hash...
       any:  0 wallclock secs ( 0.67 usr +  0.00 sys =  0.67 CPU) @ 149253.73/s (n=100000)
     first:  1 wallclock secs ( 0.63 usr +  0.01 sys =  0.64 CPU) @ 156250.00/s (n=100000)
      grep: 42 wallclock secs (41.95 usr +  0.08 sys = 42.03 CPU) @ 2379.25/s (n=100000)
      hash:  0 wallclock secs ( 0.01 usr +  0.00 sys =  0.01 CPU) @ 10000000.00/s (n=100000)
            (warning: too few iterations for a reliable count)

@files是一个已存在的数组

my @new_values =  grep(/^2[\d].[\d][A-za-z]?/,@files);

print join("\n", @new_values);

print "\n";

/ ^ 2 \ [d]。[\ d] [A-za-z]吗?/ =从2开始的值这里可以放入任何正则表达式

简单地将数组转换为哈希:

my %params = map { $_ => 1 } @badparams;

if(exists($params{$someparam})) { ... }

你也可以添加更多(唯一的)参数到列表中:

$params{$newparam} = 1;

然后返回一个(唯一的)参数列表:

@badparams = keys %params;