一个可能的解决方案:

    /#include/!{p;d;}
    i\
    #include "newfile.h"
    :a
    n
    ba

解释:

读取行，直到找到#include，打印这些行，然后开始新的循环 插入新的包含行 输入一个只读取行(默认情况下sed也会打印这些行)的循环，我们不会从这里回到脚本的第一部分

sed '0,/pattern/s/pattern/replacement/' filename

这对我很管用。

例子

sed '0,/<Menu>/s/<Menu>/<Menu><Menu>Sub menu<\/Menu>/' try.txt > abc.txt

编者注:两者都只适用于GNU sed。

我终于得到了这个工作在一个Bash脚本用来插入一个唯一的时间戳在每个项目在RSS提要:

        sed "1,/====RSSpermalink====/s/====RSSpermalink====/${nowms}/" \
            production-feed2.xml.tmp2 > production-feed2.xml.tmp.$counter

它只改变第一个事件。

${nowms}是Perl脚本设置的以毫秒为单位的时间，$counter是脚本中用于循环控制的计数器，\允许命令在下一行继续执行。

文件被读入，stdout被重定向到工作文件。

我理解它的方式，1，/====RSSpermalink====/告诉sed什么时候通过设置范围限制来停止，然后s/====RSSpermalink====/${nowms}/是熟悉的sed命令，用第二个字符串替换第一个字符串。

在我的例子中，我把命令放在双引号中，因为我在一个带有变量的Bash脚本中使用它。

使用FreeBSD ed，避免ed在文件中没有include语句时出现“no match”错误:

teststr='
#include <stdio.h>
#include <stdlib.h>
#include <inttypes.h>
'

# using FreeBSD ed
# to avoid ed's "no match" error, see
# *emphasized text*http://codesnippets.joyent.com/posts/show/11917 
cat <<-'EOF' | sed -e 's/^ *//' -e 's/ *$//' | ed -s <(echo "$teststr")
   H
   ,g/# *include/u\
   u\
   i\
   #include "newfile.h"\
   .
   ,p
   q
EOF

我会用一个awk脚本来做到这一点:

BEGIN {i=0}
(i==0) && /#include/ {print "#include \"newfile.h\""; i=1}
{print $0}    
END {}

然后用awk运行它:

awk -f awkscript headerfile.h > headerfilenew.h

可能有点草率，我是新手。

#!/bin/sed -f
1,/^#include/ {
    /^#include/i\
#include "newfile.h"
}

该脚本的工作原理:对于第1行和第一个#include(在第1行之后)之间的行，如果该行以#include开头，则在指定的行前面加上。

但是，如果第一个#include在第1行，那么第1行和下一个#include都将有该行前置。如果您正在使用GNU sed，它有一个扩展，其中0，/^#include/(而不是1，)将做正确的事情。