这可能为你工作(GNU sed):

sed -si '/#include/{s//& "newfile.h\n&/;:a;$!{n;ba}}' file1 file2 file....

或者如果内存不是问题:

sed -si ':a;$!{N;ba};s/#include/& "newfile.h\n&/' file1 file2 file...

#!/bin/sed -f
1,/^#include/ {
    /^#include/i\
#include "newfile.h"
}

该脚本的工作原理:对于第1行和第一个#include(在第1行之后)之间的行，如果该行以#include开头，则在指定的行前面加上。

但是，如果第一个#include在第1行，那么第1行和下一个#include都将有该行前置。如果您正在使用GNU sed，它有一个扩展，其中0，/^#include/(而不是1，)将做正确的事情。

一个可能的解决方案:

    /#include/!{p;d;}
    i\
    #include "newfile.h"
    :a
    n
    ba

解释:

读取行，直到找到#include，打印这些行，然后开始新的循环 插入新的包含行 输入一个只读取行(默认情况下sed也会打印这些行)的循环，我们不会从这里回到脚本的第一部分

作为一种替代建议，您可能希望查看ed命令。

man 1 ed

teststr='
#include <stdio.h>
#include <stdlib.h>
#include <inttypes.h>
'

# for in-place file editing use "ed -s file" and replace ",p" with "w"
# cf. http://wiki.bash-hackers.org/howto/edit-ed
cat <<-'EOF' | sed -e 's/^ *//' -e 's/ *$//' | ed -s <(echo "$teststr")
   H
   /# *include/i
   #include "newfile.h"
   .
   ,p
   q
EOF

sed -e 's/pattern/REPLACEMENT/1' <INPUTFILE

 # sed script to change "foo" to "bar" only on the first occurrence
 1{x;s/^/first/;x;}
 1,/foo/{x;/first/s///;x;s/foo/bar/;}
 #---end of script---

或者，如果你喜欢:编辑注:只适用于GNU sed。

sed '0,/foo/s//bar/' file 

源