我在vi中打开了一个Ruby代码文件，其中有行注释为#：
class Search < ActiveRecord::Migration
def self.up
# create_table :searches do |t|
# t.integer :user_id
# t.string :name
# t.string :all_of
# t.string :any_of
# t.string :none_of
# t.string :exact_phrase
#
# t.timestamps
# end
end
def self.down
# drop_table :searches
end
end
假设我想取消注释第一个定义中的所有行。。。端部。在Vim中有什么有效的方法可以做到这一点？
总的来说，我正在寻找一种简单、流畅的方式来注释和取消注释行。这里我处理的是Ruby代码，但可能是JavaScript（//）或Haml（-#）。
当前回答
我使用vim多个光标。
要选择区域，请按0（它是零，而不是字母“o”）转到要注释掉的区域的第一行或最后一行的第一个字符。然后按V键并使用J、K或上下箭头键选择区域。然后按CtrlN将虚拟光标放在选择的每一行上。然后按I键同时编辑选择的每一行。
其他回答
我个人不喜欢注释“切换”功能，因为它会破坏代码中已经包含的注释。此外，我希望注释字符始终显示在最左边，这样我可以很容易地看到注释块。此外，我希望这是嵌套的（如果我首先注释掉一个块，然后是一个封闭块）。因此，我稍微改变了其中一个解决方案。我使用F5注释，使用Shift-F5取消注释。此外，我在s/命令末尾添加了/g：
autocmd FileType c,cpp,java,scala let b:comment_leader = '//'
autocmd FileType sh,ruby,python let b:comment_leader = '#'
autocmd FileType conf,fstab let b:comment_leader = '#'
autocmd FileType tex let b:comment_leader = '%'
autocmd FileType mail let b:comment_leader = '>'
autocmd FileType vim let b:comment_leader = '"'
autocmd FileType nasm let b:comment_leader = ';'
function! CommentLine()
execute ':silent! s/^\(.*\)/' . b:comment_leader . ' \1/g'
endfunction
function! UncommentLine()
execute ':silent! s/^' . b:comment_leader . ' //g'
endfunction
map <F5> :call CommentLine()<CR>
map <S-F5> :call UncommentLine()<CR>
" comments
augroup comment_like_a_boss
autocmd!
autocmd FileType c,cpp,go let b:comment_leader = '// '
autocmd FileType ruby,python let b:comment_leader = '# '
autocmd FileType conf,fstab,sh,bash,tmux let b:comment_leader = '# '
autocmd FileType tex let b:comment_leader = '% '
autocmd FileType mail let b:comment_leader = '> '
autocmd FileType vim let b:comment_leader = '" '
augroup END
noremap <silent> ,cc :<C-b>silent <C-e>norm ^i<C-r>=b:comment_leader<CR><CR>
noremap <silent> ,uc :<C-b>silent <C-e>norm ^xx<CR>
是的，这个问题已经有33个（大部分是重复的）答案。
下面是另一种在Vim中注释行的方法：运动。基本思想是使用与键入yip删除段落或键入dj删除2行相同的方法注释或取消注释行。
这种方法可以让您执行以下操作：
ccj注释接下来的2行，cuk取消注释；cci{注释一个块，cui{取消注释；ccip注释整个段落，cuip取消注释。ccG将所有内容注释到最后一行，cugg将所有内容取消注释到第一行。
您只需要2个对运动进行操作的函数，以及每个函数的2个映射。首先，映射：
nnoremap <silent> cc :set opfunc=CommentOut<cr>g@
vnoremap <silent> cc :<c-u>call CommentOut(visualmode(), 1)<cr>
nnoremap <silent> cu :set opfunc=Uncomment<cr>g@
vnoremap <silent> cu :<c-u>call Uncomment(visualmode(), 1)<cr>
（请参阅有关g@运算符和operatorfunc变量的手册。）
现在功能如下：
function! CommentOut(type, ...)
if a:0
silent exe "normal! :'<,'>s/^/#/\<cr>`<"
else
silent exe "normal! :'[,']s/^/#/\<cr>'["
endif
endfunction
function! Uncomment(type, ...)
if a:0
silent exe "normal! :'<,'>s/^\\(\\s*\\)#/\\1/\<cr>`<"
else
silent exe "normal! :'[,']s/^\\(\\s*\\)#/\\1/\<cr>`["
endif
endfunction
修改上面的正则表达式以适合您的口味，即#应该在哪里：
首先，我要感谢@mike的回答，因为我使用的是它的修改版本。我想发布我的版本，以防有人感兴趣。我的主要功能区别在于，它将始终在射程的每一行上执行相同的动作。如果所选范围包含任何未注释的行，则每一行都会添加注释引线。这样，如果在未注释的代码块中有人类可读的注释，则它们不会变为未注释。然后，当您取消注释块时，人类可读的文本将保持注释状态，因为它有两个注释引线。完成后，它还会恢复光标位置。
ToggleComment函数：
function! ToggleComment() range
"Ensure we know the comment leader.
if !exists('b:comment_leader')
echo "Unknown comment leader."
return
endif
"Save the initial cursor position, to restore later.
let l:inipos = getpos('.')
"Make a list of all of the line numbers in the range which are already commented.
let l:commented_lines = []
for i in range(a:firstline, a:lastline)
if getline(i) =~ '^\s*' . b:comment_leader
let l:commented_lines = add(l:commented_lines, i)
endif
endfor
"If every line in the range is commented, set the action to uncomment.
" Otherwise, set it to comment.
let l:i1 = index(l:commented_lines, a:firstline)
let l:i2 = index(l:commented_lines, a:lastline)
if l:i1 >= 0 && l:i2 >= 0 && (l:i2 - l:i1) == (a:lastline - a:firstline)
let l:action = "uncomment"
else
let l:action = "comment"
endif
"Loop through the range, commenting or uncommenting based on l:action.
for i in range(a:firstline, a:lastline)
"Move to line i.
exec "exe " . i
"Perform the action.
if l:action == "comment"
exec 'normal! 0i' . b:comment_leader
else
execute 'silent s,' . b:comment_leader . ',,'
endif
endfor
"Restore the initial position.
call setpos('.', l:inipos)
endfunction
键映射（注意，我将注释键更改为“k”）：
noremap <Leader>k :call ToggleComment()<CR>
最后，我将autocmds放在下面的“if”语句和augroup中，但它们保持不变。它们大多只是供参考。
if has("autocmd")
augroup autocmds
autocmd!
autocmd FileType c,cpp,java let b:comment_leader = '//'
autocmd FileType arduino let b:comment_leader = '//'
autocmd FileType sh,ruby,python let b:comment_leader = '#'
autocmd FileType zsh let b:comment_leader = '#'
autocmd FileType conf,fstab let b:comment_leader = '#'
autocmd FileType matlab,tex let b:comment_leader = '%'
autocmd FileType vim let b:comment_leader = '"'
augroup END
endif
编辑：我从原始答案更新了ToggleComment函数。最重要的是，我修改了正则表达式。在许多情况下，如果字符串中有另一个注释引线实例，它将无法正常工作。我相信它可能必须在前面或后面加一个空格，但我记不起来了。不管怎样，下面是Python的错误示例。
print("Hello, World!") # Says hello to the world.
我已经解决了这个问题，并稍微简化了正则表达式。一个副作用是它不再在评论标题后面添加空格，但这并不困扰我。我在一些变量中添加了一个局部声明，我在最初的答案中忘记了这些变量。
我使用Jasmeet Singh Anand的comments.vim（在vim.org上找到），
它适用于C、C++、Java、PHP[2345]、proc、CSS、HTML、htm、XML、XHTML、vim、vimrc、SQL、sh、ksh、csh、Perl、tex、fortran、ml、caml、ocaml、vhdl、haskel和普通文件
它在正常和可视模式下对不同源文件中的行进行注释和取消注释
用法：
CtrlC注释单行CtrlX取消注释单行ShiftV并选择多行，然后CtrlC对所选多行进行注释ShiftV并选择多行，然后CtrlX取消注释所选多行
