我在vi中打开了一个Ruby代码文件，其中有行注释为#：
class Search < ActiveRecord::Migration
def self.up
# create_table :searches do |t|
# t.integer :user_id
# t.string :name
# t.string :all_of
# t.string :any_of
# t.string :none_of
# t.string :exact_phrase
#
# t.timestamps
# end
end
def self.down
# drop_table :searches
end
end
假设我想取消注释第一个定义中的所有行。。。端部。在Vim中有什么有效的方法可以做到这一点？
总的来说，我正在寻找一种简单、流畅的方式来注释和取消注释行。这里我处理的是Ruby代码，但可能是JavaScript（//）或Haml（-#）。
当前回答
首先，我要感谢@mike的回答，因为我使用的是它的修改版本。我想发布我的版本，以防有人感兴趣。我的主要功能区别在于，它将始终在射程的每一行上执行相同的动作。如果所选范围包含任何未注释的行，则每一行都会添加注释引线。这样，如果在未注释的代码块中有人类可读的注释，则它们不会变为未注释。然后，当您取消注释块时，人类可读的文本将保持注释状态，因为它有两个注释引线。完成后，它还会恢复光标位置。
ToggleComment函数：
function! ToggleComment() range
"Ensure we know the comment leader.
if !exists('b:comment_leader')
echo "Unknown comment leader."
return
endif
"Save the initial cursor position, to restore later.
let l:inipos = getpos('.')
"Make a list of all of the line numbers in the range which are already commented.
let l:commented_lines = []
for i in range(a:firstline, a:lastline)
if getline(i) =~ '^\s*' . b:comment_leader
let l:commented_lines = add(l:commented_lines, i)
endif
endfor
"If every line in the range is commented, set the action to uncomment.
" Otherwise, set it to comment.
let l:i1 = index(l:commented_lines, a:firstline)
let l:i2 = index(l:commented_lines, a:lastline)
if l:i1 >= 0 && l:i2 >= 0 && (l:i2 - l:i1) == (a:lastline - a:firstline)
let l:action = "uncomment"
else
let l:action = "comment"
endif
"Loop through the range, commenting or uncommenting based on l:action.
for i in range(a:firstline, a:lastline)
"Move to line i.
exec "exe " . i
"Perform the action.
if l:action == "comment"
exec 'normal! 0i' . b:comment_leader
else
execute 'silent s,' . b:comment_leader . ',,'
endif
endfor
"Restore the initial position.
call setpos('.', l:inipos)
endfunction
键映射（注意，我将注释键更改为“k”）：
noremap <Leader>k :call ToggleComment()<CR>
最后，我将autocmds放在下面的“if”语句和augroup中，但它们保持不变。它们大多只是供参考。
if has("autocmd")
augroup autocmds
autocmd!
autocmd FileType c,cpp,java let b:comment_leader = '//'
autocmd FileType arduino let b:comment_leader = '//'
autocmd FileType sh,ruby,python let b:comment_leader = '#'
autocmd FileType zsh let b:comment_leader = '#'
autocmd FileType conf,fstab let b:comment_leader = '#'
autocmd FileType matlab,tex let b:comment_leader = '%'
autocmd FileType vim let b:comment_leader = '"'
augroup END
endif
编辑：我从原始答案更新了ToggleComment函数。最重要的是，我修改了正则表达式。在许多情况下，如果字符串中有另一个注释引线实例，它将无法正常工作。我相信它可能必须在前面或后面加一个空格，但我记不起来了。不管怎样，下面是Python的错误示例。
print("Hello, World!") # Says hello to the world.
我已经解决了这个问题，并稍微简化了正则表达式。一个副作用是它不再在评论标题后面添加空格，但这并不困扰我。我在一些变量中添加了一个局部声明，我在最初的答案中忘记了这些变量。
其他回答
从这里的答案中的想法开始，我开始了自己的评论功能。它可以打开和关闭评论。它可以处理//打印（“蓝色”）等事情//这个东西是蓝色的，只是切换第一条评论。此外，它在第一个非空白处添加注释和一个空格，而不是在行的开头。另外，在注释和缩进行时，它不会不必要地复制空白，而是使用缩放（：h\zs表示帮助）来避免这种额外的工作。希望它能帮助一些极简主义者。欢迎提出建议。
" these lines are needed for ToggleComment()
autocmd FileType c,cpp,java let b:comment_leader = '//'
autocmd FileType arduino let b:comment_leader = '//'
autocmd FileType sh,ruby,python let b:comment_leader = '#'
autocmd FileType zsh let b:comment_leader = '#'
autocmd FileType conf,fstab let b:comment_leader = '#'
autocmd FileType matlab,tex let b:comment_leader = '%'
autocmd FileType vim let b:comment_leader = '"'
" l:pos --> cursor position
" l:space --> how many spaces we will use b:comment_leader + ' '
function! ToggleComment()
if exists('b:comment_leader')
let l:pos = col('.')
let l:space = ( &ft =~ '\v(c|cpp|java|arduino)' ? '3' : '2' )
if getline('.') =~ '\v(\s*|\t*)' .b:comment_leader
let l:space -= ( getline('.') =~ '\v.*\zs' . b:comment_leader . '(\s+|\t+)@!' ? 1 : 0 )
execute 'silent s,\v^(\s*|\t*)\zs' .b:comment_leader.'[ ]?,,g'
let l:pos -= l:space
else
exec 'normal! 0i' .b:comment_leader .' '
let l:pos += l:space
endif
call cursor(line("."), l:pos)
else
echo 'no comment leader found for filetype'
end
endfunction
nnoremap <Leader>t :call ToggleComment()<CR>
inoremap <Leader>t <C-o>:call ToggleComment()<CR>
xnoremap <Leader>t :'<,'>call ToggleComment()<CR>
指定要在vim中注释的行：
显示行号：
:set number
然后
:5,17s/^/#/ this will comment out line 5-17
或者：
:%s/^/#/ will comment out all lines in file
有时我会被推到一个远程盒子里，我的插件和.vimrc无法帮助我，或者有时NerdCommenter会出错（例如嵌入HTML中的JavaScript）。
在这些情况下，一种低技术的替代方法是内置的norm命令，它只在指定范围内的每一行运行任意vim命令。例如：
评论#：
1. visually select the text rows (using V as usual)
2. :norm i#
这将在每行的开头插入“#”。请注意，当您键入：范围将被填充，因此它看起来真的像：'<，'>norm i#
取消注释#：
1. visually select the text as before (or type gv to re-select the previous selection)
2. :norm x
这将删除每行的第一个字符。如果我使用了一个2个字符的注释，比如//，那么我只需要：norm xx来删除这两个字符。
如果注释如OP问题中那样缩进，那么您可以这样锚定删除：
:norm ^x
意思是“转到第一个非空格字符，然后删除一个字符”。请注意，与块选择不同，即使注释有不均匀的缩进，此技术也有效！
注意：由于norm实际上只是执行常规的vim命令，所以您不限于注释，还可以对每一行进行一些复杂的编辑。如果需要将转义符作为命令序列的一部分，请键入ctrl-v，然后按转义键（或者更简单，只需录制一个快速宏，然后使用norm在每行上执行该宏）。
注2：如果您发现自己经常使用规范，当然也可以添加映射。例如，在~/.vimrc中放入以下行可以让您在进行视觉选择后键入ctrl-n而不是：norm
vnoremap <C-n> :norm
注意3：裸骨vim有时没有编译规范命令，因此请确保使用增强版本，即通常为/usr/bin/vim，而不是/bin/vi
（感谢@Manbroski和@rakslice对本答案的改进）
是的，这个问题已经有33个（大部分是重复的）答案。
下面是另一种在Vim中注释行的方法：运动。基本思想是使用与键入yip删除段落或键入dj删除2行相同的方法注释或取消注释行。
这种方法可以让您执行以下操作：
ccj注释接下来的2行，cuk取消注释；cci{注释一个块，cui{取消注释；ccip注释整个段落，cuip取消注释。ccG将所有内容注释到最后一行，cugg将所有内容取消注释到第一行。
您只需要2个对运动进行操作的函数，以及每个函数的2个映射。首先，映射：
nnoremap <silent> cc :set opfunc=CommentOut<cr>g@
vnoremap <silent> cc :<c-u>call CommentOut(visualmode(), 1)<cr>
nnoremap <silent> cu :set opfunc=Uncomment<cr>g@
vnoremap <silent> cu :<c-u>call Uncomment(visualmode(), 1)<cr>
（请参阅有关g@运算符和operatorfunc变量的手册。）
现在功能如下：
function! CommentOut(type, ...)
if a:0
silent exe "normal! :'<,'>s/^/#/\<cr>`<"
else
silent exe "normal! :'[,']s/^/#/\<cr>'["
endif
endfunction
function! Uncomment(type, ...)
if a:0
silent exe "normal! :'<,'>s/^\\(\\s*\\)#/\\1/\<cr>`<"
else
silent exe "normal! :'[,']s/^\\(\\s*\\)#/\\1/\<cr>`["
endif
endfunction
修改上面的正则表达式以适合您的口味，即#应该在哪里：
我喜欢简短的、综合的、令人难忘的方法，不依赖于外部脚本——一种花哨的小题大做。。。
TLDR：按gI（大写i）将光标置于插入模式下的行首（无论是空格还是非空格字符，并防止自动缩进）
使用此选项可快速注释（例如）非连续行，注释符号（例如#或//）为第一个字符，不带缩进，方法是按。（点）-->，但如果仍有自动缩进机制，则在插入模式下按和以更正缩进，操作后退出到正常模式。现在可用于注释行。。。
长：我现在（几年后）意识到，按gI（大写I）会将光标置于插入模式下的第1列（意思是：无论是单词还是非单词字符，都在行的开头）。
插入注释符号（如#）并按escape-现在可以在只按的同时注释单个非连续行（注释符号作为第一个字符，没有缩进）。（点）。
与按0i或仅按I相反，它将注释符号放在第一个单词字符处，部分还带有不需要的缩进
