为了补充josh的回答，

您可以通过以下步骤使别名持久，

用DOSKEY命令创建一个.bat或.cmd文件。 运行regedit，进入HKEY_CURRENT_USER\Software\Microsoft\Command Processor 添加字符串值条目，名称为AutoRun和.bat/的完整路径。cmd文件。 例如，%USERPROFILE%\alias。在命令cmd中，用%USERPROFILE%替换路径的初始段对于多台机器之间的同步很有用。

这样，每次运行cmd时，都会加载别名。

对于Windows 10或Windows 11，请将该条目添加到HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Command Processor中。

(对于Windows 11，还要注意默认情况下“终端应用程序”指向PowerShell。搜索“cmd”命令提示符。)

为了完整起见，这里有一个模板来说明可能有用的别名类型。

@echo off

:: Temporary system path at cmd startup

set PATH=%PATH%;"C:\Program Files\Sublime Text 2\"

:: Add to path by command

DOSKEY add_python26=set PATH=%PATH%;"C:\Python26\"
DOSKEY add_python33=set PATH=%PATH%;"C:\Python33\"

:: Commands

DOSKEY ls=dir /B $*
DOSKEY sublime=sublime_text $*  
    ::sublime_text.exe is name of the executable. By adding a temporary entry to system path, we don't have to write the whole directory anymore.
DOSKEY gsp="C:\Program Files (x86)\Sketchpad5\GSP505en.exe"
DOSKEY alias=notepad %USERPROFILE%\Dropbox\alias.cmd

:: Common directories

DOSKEY dropbox=cd "%USERPROFILE%\Dropbox\$*"
DOSKEY research=cd %USERPROFILE%\Dropbox\Research\

请注意，$*语法适用于目录字符串之后，也适用于带有参数的可执行文件之后。因此，在上面的示例中，用户定义的命令dropbox research指向与research相同的目录。 正如Rivenfall所指出的，包含一个允许方便地编辑别名的命令是一个好主意。cmd文件。参见上面的别名。如果您在一个cmd会话中，输入cmd重新启动cmd并重新加载别名。cmd文件。

当我在互联网上搜索这个问题的答案时，不知怎么的，讨论要么只集中在持久性上，要么只集中在DOSKEY的某些用法上。我希望在这里有人能从这两方面受益!

这里有一个.reg文件来帮助你安装别名。cmd。现在将它设置为上面建议的dropbox文件夹的示例。

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Software\Microsoft\Command Processor]
"AutoRun"="%USERPROFILE%\\alias.cmd"

对于单用户应用程序，上面的方法就可以了。不过，也有一些情况需要检查是否存在别名。CMD首先存在于注册表项中。参见下面的示例。

C:\Users\Public\init.CMD文件承载潜在的跨用户配置:

@ECHO OFF
REM Add other configurations as needed
IF EXIST "%USERPROFILE%\alias.cmd" ( CALL "%USERPROFILE%\alias.cmd" )

注册表项应相应更新为C:\Users\Public\init.CMD或使用.reg文件:

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Software\Microsoft\Command Processor]
"AutoRun"="C:\\Users\\Public\\init.cmd"

你要创建一个别名，只需输入:

c:\>alias kgs kubectl get svc

Created alias for kgs=kubectl get svc

并使用别名如下:

c:\>kgs alfresco-svc

NAME           TYPE        CLUSTER-IP     EXTERNAL-IP   PORT(S)   AGE
alfresco-svc   ClusterIP   10.7.249.219   <none>        80/TCP    8d

只需将以下alias.bat文件添加到您的路径。它只是在与自身相同的目录中创建额外的批处理文件。

  @echo off
  echo.
  for /f "tokens=1,* delims= " %%a in ("%*") do set ALL_BUT_FIRST=%%b
  echo @echo off > C:\Development\alias-script\%1.bat
  echo echo. >> C:\Development\alias-script\%1.bat
  echo %ALL_BUT_FIRST% %%* >> C:\Development\alias-script\%1.bat
  echo Created alias for %1=%ALL_BUT_FIRST%

创建的批处理文件名为kgs.bat的示例如下:

@echo off 
echo. 
kubectl get svc %* 

或者你也可以使用cder，它可以让你像linux一样添加别名:

alias subl="C:\Program Files\Sublime Text 3\subl.exe" $*

扩展罗里休伊特的回答。

在DOSKEY上使用.cmd文件的一个优势是，这些“别名”可以在其他shell中使用，如PowerShell或WSL (Linux的Windows子系统)。

在bash中使用这些命令的唯一缺点是可能需要更多的设置，因为在调用“别名”之前可能需要进行一些路径操作。

我有vs.cmd，这是我在Visual Studio编辑文件的“别名”

@echo off
if [%1]==[] goto nofiles
start "" "c:\Program Files (x86)\Microsoft Visual Studio 
11.0\Common7\IDE\devenv.exe" /edit %1
goto end
:nofiles
start "" "C:\Program Files (x86)\Microsoft Visual Studio 
11.0\Common7\IDE\devenv.exe" "[PATH TO MY NORMAL SLN]"
:end

它会点燃VS(在这种情况下VS2012 -但调整口味)使用我的“正常”项目，没有文件，但当给出一个文件时，将试图附加到一个运行的VS打开该文件“在该项目中”，而不是开始一个新的VS实例。

为了从bash使用这个，我然后添加了一个额外的间接级别，因为“vs Myfile”并不总是工作

alias vs='/usr/bin/run_visual_studio.sh'

在调用vs.cmd之前调整路径

#!/bin/bash
cmd.exe /C 'c:\Windows\System32\vs.cmd' "`wslpath.sh -w -r $1`"

这样我就可以

vs SomeFile.txt

在命令提示符中，Power Shell或bash，它在我运行的Visual Studio中打开进行编辑(当我在VS中编辑了几个小时时，这只是让我可怜的大脑不必处理VI命令或其他类似的命令)。

假设您将notepad++.exe添加到PATH变量中，这就非常简单了。 用以下代码在System32文件夹中创建一个名为np.bat的文件:

@echo off
call notepad++.exe %*

%*将您赋予np命令的所有参数传递给notepad++.exe命令。

编辑: 您需要管理员权限才能将文件保存到System32文件夹，这对我来说有点不可靠。我只是在其他地方创建了该文件，并手动将其移动到System32。

首先，您可以创建一个名为np的文件。cmd并将其放在PATH搜索列表中的文件夹中。 然后，编辑np。CMD文件如下所示:

@echo off
notepad++.exe