使用DATENAME或DATEPART:

SELECT DATENAME(dw,GETDATE()) -- Friday
SELECT DATEPART(dw,GETDATE()) -- 6

尽管SQLMenace的答案已经被接受，但是您应该注意一个重要的SET选项

设置DATEFIRST

如果一周的第一天发生了如下所示的变化，那么DATENAME将返回正确的日期名称，但不是相同的DATEPART值。

declare @DefaultDateFirst int
set @DefaultDateFirst = @@datefirst
--; 7 First day of week is "Sunday" by default
select  [@DefaultDateFirst] = @DefaultDateFirst 
    
set datefirst @DefaultDateFirst
select datename(dw,getdate()) -- Saturday
select datepart(dw,getdate()) -- 7

--; Set the first day of week to * TUESDAY * 
--; (some people start their week on Tuesdays...)
set datefirst 2
select datename(dw,getdate()) -- Saturday
--; Returns 5 because Saturday is the 5th day since Tuesday.
--; Tue 1, Wed 2, Th 3, Fri 4, Sat 5
select datepart(dw,getdate()) -- 5 <-- It's not 7!
set datefirst @DefaultDateFirst

要获得给定日期的星期几的确定值，可以使用DATEPART()和@@datefirst的组合。否则你将依赖于服务器上的设置。

请访问以下网站寻找更好的解决方案: MS SQL:星期的一天

然后，星期几将在0到6的范围内，其中0是星期天，1是星期一，等等。然后可以使用简单的case语句返回正确的工作日名称。

SELECT  CASE DATEPART(WEEKDAY,GETDATE())  
    WHEN 1 THEN 'SUNDAY' 
    WHEN 2 THEN 'MONDAY' 
    WHEN 3 THEN 'TUESDAY' 
    WHEN 4 THEN 'WEDNESDAY' 
    WHEN 5 THEN 'THURSDAY' 
    WHEN 6 THEN 'FRIDAY' 
    WHEN 7 THEN 'SATURDAY' 
END

这是一个工作副本的我的代码检查它，如何从日期检索日期名称在SQL

CREATE Procedure [dbo].[proc_GetProjectDeploymentTimeSheetData] 
@FromDate date,
@ToDate date

As 
Begin
select p.ProjectName + ' ( ' + st.Time +' '+'-'+' '+et.Time +' )' as ProjectDeatils,
datename(dw,pts.StartDate) as 'Day'
from 
ProjectTimeSheet pts 
join Projects p on pts.ProjectID=p.ID 
join Timing st on pts.StartTimingId=st.Id
join Timing et on pts.EndTimingId=et.Id
where pts.StartDate >= @FromDate
and pts.StartDate <= @ToDate
END

您可能会发现这个版本用于在一行中返回缩短的工作日名称。

-- Test DATA
select @@datefirst
create table #test (datum datetime)
insert #test values ('2013-01-01')
insert #test values ('2013-01-02')
insert #test values ('2013-01-03')
insert #test values ('2013-01-04')
insert #test values ('2013-01-05')
insert #test values ('2013-01-06')
insert #test values ('2013-01-07')
insert #test values ('2013-01-08')
-- Test DATA

select  Substring('Sun,Mon,Tue,Wed,Thu,Fri,Sat,Sun,Mon,Tue,Wed,Thu,Fri,Sat',
        (DATEPART(WEEKDAY,datum)+@@datefirst-1)*4+1,3),Datum
        from #test 

欧洲:

declare @d datetime;
set @d=getdate();
set @dow=((datepart(dw,@d) + @@DATEFIRST-2) % 7+1);

在SQL Server 2012及以后的版本中，您可以使用FORMAT函数

SELECT FORMAT(GETDATE(), 'dddd')

如果您不想依赖于@@DATEFIRST或使用DATEPART(weekday, DateColumn)，只需自己计算星期几即可。

对于以周一为基准的周(欧洲)，最简单的方法是:

SELECT DATEDIFF(day, '17530101', DateColumn) % 7 + 1 AS MondayBasedDay

对于星期日为基础的周(美国)使用:

SELECT DATEDIFF(day, '17530107', DateColumn) % 7 + 1 AS SundayBasedDay

这返回了自1753年1月1日以来的工作日数字(1到7)。

您可以使用DATEPART(dw, GETDATE())，但请注意，结果将依赖于SQL服务器设置@@DATEFIRST值，这是一周的第一天设置(在欧洲默认值7，这是星期天)。

如果你想将一周的第一天更改为另一个值，你可以使用SET DATEFIRST，但这可能会影响到你不想要的查询会话中的所有地方。

另一种方法是显式地指定一周的第一天值作为参数，并避免依赖于@@DATEFIRST设置。当需要时，你可以使用下面的公式来实现:

(DATEPART(dw, GETDATE()) + @@DATEFIRST + 6 - @WeekStartDay) % 7 + 1

@WeekStartDay是你的系统想要的一周的第一天(从1到7，这意味着从周一到周日)。

我把它包装成下面的函数，这样我们可以很容易地重用它:

CREATE FUNCTION [dbo].[GetDayInWeek](@InputDateTime DATETIME, @WeekStartDay INT)
RETURNS INT
AS
BEGIN
    --Note: @WeekStartDay is number from [1 - 7] which is from Monday to Sunday
    RETURN (DATEPART(dw, @InputDateTime) + @@DATEFIRST + 6 - @WeekStartDay) % 7 + 1 
END

使用示例: GetDayInWeek('2019-02-04 00:00:00'， 1)

它等价于以下(但独立于SQL server DATEFIRST设置):

SET DATEFIRST 1
DATEPART(dw, '2019-02-04 00:00:00')

另外，以上所有答案中，dw代表Week Day

SELECT DATENAME(WEEKDAY,GETDATE()) AS WeekDay

or

SELECT DATENAME(W,GETDATE()) AS WeekDay