使用Windows PowerShell，您可以使用:

Get-Content <file> -Wait

我建议为Win32安装GNU实用程序。它有最喜欢的，包括尾巴。

我使用Tail For Windows。当然没有使用tail那么优雅，但这是在使用Windows。；）

我写了这个批处理脚本。它不像Unix的“尾巴”那么复杂，但希望有人可以添加它来改进它，比如将输出限制在文件的最后10行，等等。如果你确实改进了这个脚本，请发送给我在抢劫~[at]~ gmail.com。

@echo off

:: This is a batch script I wrote to mimic the 'tail' UNIX command.
:: It is far from perfect, but I am posting it in the hopes that it will
:: be improved by other people. This was designed to work on Windows 7.
:: I have not tested it on any other versions of Windows

if "%1" == "" goto noarg
if "%1" == "/?" goto help
if "%1" == "-?" goto help
if NOT EXIST %1 goto notfound
set taildelay=%2
if "%taildelay%"=="" set taildelay=1

:loop
cls
type %1

:: I use the CHOICE command to create a delay in batch.

CHOICE /C YN /D Y /N /T %taildelay%
goto loop

:: Error handlers

:noarg
echo No arguments given. Try /? for help.
goto die

:notfound
echo The file '%1' could not be found.
goto die

:: Help text

:help
echo TAIL filename [seconds]

:: I use the call more pipe as a way to insert blank lines since echo. doesnt
:: seem to work on Windows 7

call | more
echo Description:
echo     This is a Windows version of the UNIX 'tail' command.
echo     Written completely from scratch by Andrey G.
call | more
echo Parameters:
echo    filename             The name of the file to display
call | more
echo    [seconds]            The number of seconds to delay before reloading the
echo                         file and displaying it again. Default is set to 1
call | more
echo ú  /?                   Displays this help message
call | more
echo    NOTE:
echo    To exit while TAIL is running, press CTRL+C.
call | more
echo Example:
echo    TAIL foo 5
call | more
echo    Will display the contents of the file 'foo',
echo    refreshing every 5 seconds.
call | more

:: This is the end

:die

尝试UNIX的Windows服务。提供shell, awk, sed等以及尾部。

更新-:不幸的是，截至2019年，该系统不再适用于微软下载中心。

如果你根本不想安装任何东西，你可以用标准的Windows命令“构建你自己的”批处理文件。这里有一些关于如何做到这一点的建议。

1)使用find /c /v "" yourinput。文件，获取输入文件中的行数。输出如下所示:

---------- T.TXT: 15

2)使用for /f，解析此输出以得到数字15。

3)使用set /a，计算需要跳过的标题行数

4)使用for /f "skip=n"跳过头部行，回显/处理尾部行。

如果我有时间，我将构建这样一个批处理文件，并将其发布回这里。

编辑:tail.bat

REM tail.bat
REM
REM Usage: tail.bat <file> <number-of-lines> 
REM
REM Examples: tail.bat myfile.txt 10
REM           tail.bat "C:\My File\With\Spaces.txt" 10

@ECHO OFF
for /f "tokens=2-3 delims=:" %%f in ('find /c /v "" %1') do (
    for %%F in (%%f %%g) do set nbLines=%%F )
set /a nbSkippedLines=%nbLines%-%2
for /f "usebackq skip=%nbSkippedLines% delims=" %%d in (%1) do echo %%d