从SQL Server 2016开始，你可以只使用IF EXISTS关键字。

ALTER TABLE dbo.ChannelPlayerSkins
    DROP CONSTRAINT IF EXISTS FK_ChannelPlayerSkins_Channels

我使用的是SQL Server 2019，但这里提到它自SQL Server 2016以来就可用了。

SQL Server文档在ALTER TABLE页面下提到了它，而不是在Delete Check Constraints页面下。我不知道为什么。

如果存在 适用于:SQL Server (SQL Server 2016 (13.x)及以上版本)、Azure SQL数据库。 只有当列或约束已经存在时，才有条件地删除它。

只是一些需要注意的东西......

在SQL Server 2008 R2 SSMS中，“Script Constraint as -> DROP And CREATE To”命令会生成如下所示的T-SQL

USE [MyDatabase]
GO

IF  EXISTS (SELECT * FROM dbo.sysobjects WHERE id = OBJECT_ID(N'[DEF_Detail_IsDeleted]') AND type = 'D')
BEGIN
ALTER TABLE [Patient].[Detail] DROP CONSTRAINT [DEF_Detail_IsDeleted]
END

GO

USE [MyDatabase]
GO

ALTER TABLE [Patient].[Detail] ADD  CONSTRAINT [DEF_Detail_IsDeleted]  DEFAULT ((0)) FOR [IsDeleted]
GO

开箱即用时，该脚本不会删除约束，因为SELECT返回0行。(见Microsoft Connect)。

默认约束的名称是错误的，但我认为这也与OBJECT_ID函数有关，因为更改名称并不能解决问题。

为了解决这个问题，我删除了OBJECT_ID的使用，而是使用默认的约束名称。

(SELECT * FROM dbo.sysobjects WHERE [name] = (N'DEF_Detail_IsDeleted') AND type = 'D')

检查约束是否存在(然后做一些事情，比如如果存在就删除它)最简单的方法是使用OBJECT_ID()函数…

IF OBJECT_ID('dbo.[CK_ConstraintName]', 'C') IS NOT NULL 
    ALTER TABLE dbo.[tablename] DROP CONSTRAINT CK_ConstraintName

OBJECT_ID可以在没有第二个参数的情况下使用('C'仅用于检查约束)，这也可以工作，但如果您的约束名称与数据库中其他对象的名称匹配，则可能会得到意想不到的结果。

IF OBJECT_ID('dbo.[CK_ConstraintName]') IS NOT NULL 
    ALTER TABLE dbo.[tablename] DROP CONSTRAINT CK_ConstraintName

OBJECT_ID还可以与其他“约束”一起使用，如外键约束或主键约束等。为获得最佳结果，始终将适当的对象类型作为OBJECT_ID函数的第二个参数:

约束对象类型:

C = CHECK约束 D = DEFAULT(约束或独立) F =外键约束 PK =主键约束 R =规则(老式的，独立的) UQ = UNIQUE约束

还要注意，模式通常是必需的。约束的模式通常采用父表的模式。

在使用此方法时，如果没有将约束(或您正在检查的任何内容)放在括号中，也可能会导致误判——如果您的对象使用不寻常的字符(例如a .)，则需要括号。

你可以使用上面的方法，但有一个警告:

IF EXISTS(
    SELECT 1 FROM sys.foreign_keys 
    WHERE parent_object_id = OBJECT_ID(N'dbo.TableName') 
        AND name = 'CONSTRAINTNAME'
)
BEGIN 
    ALTER TABLE TableName DROP CONSTRAINT CONSTRAINTNAME 
END 

需要使用name =[约束名]，因为一个表可能有多个外键，但仍然没有外键被检查

如果你正在寻找其他类型的约束，例如默认值，你应该使用不同的查询 如何使用INFORMATION_SCHEMA找到默认约束?由devio回答)。使用:

SELECT * FROM sys.objects WHERE type = 'D' AND name = @name

按名称查找默认约束。

我已经把不同的“IF不存在”检查在我的帖子“DDL”IF不存在“条件使SQL脚本可重新运行”

SELECT tabla.name as Tabla,

        restriccion.name as Restriccion, 
        restriccion.type as Tipo, 
        restriccion.type_desc as Tipo_Desc
FROM {DATABASE_NAME}.sys.objects tabla 

INNER JOIN {DATABASE_NAME}.sys.objects restriccion

ON tabla.object_id = restriccion.parent_object_id

WHERE tabla.type = 'U' - Solo tablas creadas por el usuario.

AND restriccion.type = 'UQ' --Tipo de Restriccion UNIQUE

ORDER BY tabla.name, restriccion.type_desc