如何在批处理文件中请求管理员访问

I am trying to write a batch file for my users to run from their Vista machines with UAC. The file is re-writing their hosts file, so it needs to be run with Administrator permissions. I need to be able to send them an email with a link to the .bat file. The desired behavior is that when they right-click on the file and say Open, they will get one of those UAC dialogs that makes the screen go dark and forces them to answer whether they want to give the application permission to run as administrator. Instead, they are just seeing "Access denied" on the command line window.

有可能采取不同的做法吗?

当前回答

使用mshta提示管理员权限:

@echo off
net session >nul 2>&1 && goto :admintasks
MSHTA "javascript: var shell = new ActiveXObject('shell.application'); shell.ShellExecute('%~nx0', '', '', 'runas', 1);close();"
exit /b
:admintasks
rem ADMIN TASKS HERE

或者，使用powershell:

powershell -c Start-Process "%~nx0" -Verb runas

2020-02-22 03:10:32

其他回答

你不能从批处理文件中请求管理权限，但是你可以在%temp%中编写一个windows脚本主机脚本并运行它(它反过来以管理员身份执行你的批处理)。使用“runas”作为动词的应用程序对象

2009-12-15 16:41:29

还有来自这篇文章的FSUTIL查询，也在ss64.com上有链接，有以下代码:

@Echo Off
Setlocal
:: First check if we are running As Admin/Elevated
FSUTIL dirty query %SystemDrive% >nul
if %errorlevel% EQU 0 goto START

::Create and run a temporary VBScript to elevate this batch file
   Set _batchFile=%~f0
   Set _Args=%*
   :: double up any quotes
   Set _batchFile=""%_batchFile:"=%""
   Set _Args=%_Args:"=""%

   Echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\~ElevateMe.vbs"
   Echo UAC.ShellExecute "cmd", "/c ""%_batchFile% %_Args%""", "", "runas", 1 >> "%temp%\~ElevateMe.vbs"

   cscript "%temp%\~ElevateMe.vbs" 
   Exit /B

:START
:: set the current directory to the batch file location
cd /d %~dp0
:: Place the code which requires Admin/elevation below
Echo We are now running as admin [%1] [%2]
pause

只要FSUTIL存在，它就是一个可靠的替代方案。

2019-12-05 04:48:11

我知道这不是OP的解决方案，但是因为我确信这里还有许多其他用例，所以我想分享一下。

我对这些答案中的所有代码示例都有问题，但后来我发现: http://www.robotronic.de/runasspcEn.html

它不仅允许您以管理员身份运行，还可以检查文件以确保它没有被篡改，并安全地存储所需的信息。我承认它不是最明显的工具，但对于我们这些编写代码的人来说，它应该足够简单。

2013-05-03 03:44:20

使用mshta提示管理员权限:

@echo off
net session >nul 2>&1 && goto :admintasks
MSHTA "javascript: var shell = new ActiveXObject('shell.application'); shell.ShellExecute('%~nx0', '', '', 'runas', 1);close();"
exit /b
:admintasks
rem ADMIN TASKS HERE

或者，使用powershell:

powershell -c Start-Process "%~nx0" -Verb runas

2020-02-22 03:10:32

基于toster-cx的帖子和本页上其他有趣的帖子，我对如何配置和解决我的问题有了深入的了解。我也遇到过类似的问题，我希望磁盘清理工具每周在周一和周四的午餐时间(比如下午2点)运行两次。然而，这需要更高的权利。

共享批处理文件，这可能会帮助其他初学者像我-

@echo off
echo  Welcome to scheduling 'PC Maintenance Activity'
ping localhost -n 3 >nul
echo -- Step - 1 of 3 : Please give 'Admin' rights on next screen
ping localhost -n 5 >nul
if not "%1"=="am_admin" (powershell start -verb runas '%0' am_admin & exit)
cls
echo -- Step - 2 of 3 : In next screen, select temp areas for cleaning 
during routine scheduled activity
ping localhost -n 3 >nul
C:\Windows\System32\cleanmgr.exe /sageset:112
cls
echo    Now scheduling maintenance activity...
SchTasks /Create /SC WEEKLY /D MON,THU /TN PC_Cleanup /TR 
"C:\Windows\System32\cleanmgr.exe "/sagerun:112 /ST 14:00

cls

echo                         -- Thanks for your co-operation --
echo                    -- Maintenance activity is scheduled for --
echo                       -- Every Monday and Thursday at 2 pm --

ping localhost -n 10 >nul

非常感谢这个论坛和Rems POST在这里[https://www.petri.com/forums/forum/windows-scripting/general-scripting/32313-schtasks-exe-need-to-pass-parameters-to-script][1]

他的帖子有助于在调度任务时配置可选参数。

2018-02-02 16:25:19

如何在批处理文件中请求管理员访问

推荐文章

最新文章

标签