使用“&”

正如您注意到的那样，在没有CALL、START、CMD/C的情况下直接执行bat会导致输入并执行第一个文件，然后在第一个文件完成时停止进程。尽管您仍然可以使用&，这将与直接在控制台中使用command1&command2相同：

(
    first.bat
)&(
    second.bat
)& (
    third.bat
)&(
    echo other commands
)

就机器资源而言，这将是最有效的方法，尽管在最后一个块中，您将无法使用命令行GOTO、SHIFT、SETLOCAL。。并且其功能将与在命令提示符中执行命令几乎相同。在最后一个结束括号之后，您将无法执行其他命令

使用CALL

call first.bat
call second.bat
call third.bat

在大多数情况下，这将是最好的方法——它不创建单独的过程，但具有与调用：label作为子例程几乎相同的行为。在MS术语中，它创建一个新的“批处理文件上下文，并将控制权传递给指定标签之后的语句。第一次遇到批处理文件的结尾时（即，跳转到标签之后），控制权返回到调用语句之后的语句”

您可以使用在被调用文件中设置的变量（如果它们未在SETLOCAL块中设置），则可以直接访问被调用文件的标签。

CMD/C，管道，FOR/F

其他本机选项是使用CMD/C（/C开关将强制被调用的控制台退出并返回控制）cmd.exe在对bat文件使用FOR/F或使用管道时以非透明方式执行的操作。这将产生一个子进程，该子进程将具有调用蝙蝠的所有环境。在资源方面效率较低，但由于进程是独立的，解析崩溃或调用EXIT命令不会停止调用。bat

@echo off
CMD /c first.bat
CMD /C second.bat

::not so different than the above lines.
:: MORE,FINDSTR,FIND command will be able to read the piped data 
:: passed from the left side

break|third.bat

启动

允许您更灵活地在单独的窗口中启动脚本，不必等待脚本完成，设置标题等。默认情况下，它使用cmd/K启动.bat和.cmd脚本，这意味着派生的脚本不会自动关闭。再次将所有环境传递给已启动的脚本，并消耗比cmd/c更多的资源：

:: will be executed in the same console window and will wait to finish
start "" /b /w cmd /c first.bat 

::will start in a separate console window and WONT wait to be finished
:: the second console window wont close automatically so second.bat might need explicit exit command
start "" second.bat

::Will start it in a separate window ,but will wait to finish
:: closing the second window will cause Y/N prompt
:: in the original window 
start "" /w third.cmd


::will start it in the same console window
:: but wont wait to finish. May lead to a little bit confusing output
start "" /b cmd /c fourth.bat

WMIC

与从现在开始的其他方法不同，示例将使用CMD.exe实用程序的外部（默认情况下在Windows上仍然可用）。WMIC实用程序将创建完全独立的过程，所以您不能直接等待完成。虽然WMIC的最佳特性是它返回派生进程的id：

:: will create a separate process with cmd.exe /c
WMIC process call create "%cd%\first.bat","%cd%"

::you can get the PID and monitoring it with other tools
for /f "tokens=2 delims=;= " %%# in ('WMIC process call create "%cd%\second.bat"^,"%cd%" ^|find "ProcessId"') do (
    set "PID=%%#"
)
echo %PID%

您还可以使用它在远程计算机上启动进程，使用不同的用户等等。

SCHTASKS公司

使用SCHTASKS提供了一些功能，如（明显的）调度、以另一个用户（甚至是系统用户）的身份运行、远程机器启动等。再次在完全独立的环境（即它自己的变量）中启动它，甚至是隐藏的进程、带有命令参数的xml文件等：

SCHTASKS /create /tn BatRunner /tr "%cd%\first.bat" /sc ONCE /sd 01/01/1910 /st 00:00
SCHTASKS /Run /TN BatRunner
SCHTASKS /Delete /TN BatRunner /F

这里，也可以从事件日志中获取PID。

脚本运行程序

在启动脚本之间提供一些超时。基本事务功能（即错误回滚）和参数可以放在单独的XML文件中。

::if the script is not finished after 15 seconds (i.e. ends with pause) it will be killed
ScriptRunner.exe -appvscript %cd%\first.bat -appvscriptrunnerparameters -wait -timeout=15


::will wait or the first called script before to start the second
:: if any of the scripts exit with errorcode different than 0 will try
:: try to restore the system in the original state
ScriptRunner.exe -appvscript second.cmd arg1 arg2 -appvscriptrunnerparameters -wait -rollbackonerror -appvscript third.bat -appvscriptrunnerparameters -wait -timeout=30 -rollbackonerror

如果我们有两个批处理脚本aaa.bat和bbb.bat，并且调用如下

call aaa.bat
call bbb.bat

执行脚本时，它将首先调用aaa.bat，等待aaa.bat的线程终止，然后调用bbb.bat。

但如果您不想等待aaa.bat终止调用bbb.bat，请尝试使用START命令：

START ["title"] [/D path] [/I] [/MIN] [/MAX] [/SEPARATE | /SHARED]
  [/LOW | /NORMAL | /HIGH | /REALTIME | /ABOVENORMAL | /BELOWNORMAL]
  [/AFFINITY <hex affinity>] [/WAIT] [/B] [command/program]
  [parameters]

检查：

start /b aaa.bat
start /b bbb.bat

在一个脚本中运行多个脚本时，我遇到了相同的问题。我一直让它在第一个脚本中死去，但没有意识到它在第一脚本中退出。

:: OneScriptToRunThemAll.bat
CALL ScriptA.bat
CALL ScriptB.bat
EXIT

:: ScriptA.bat
Do Foo
EXIT
::ScriptB.bat
Do bar
EXIT

我删除了所有11个脚本EXIT行，然后再次尝试，所有11个都在同一命令窗口中依次运行。

:: OneScriptToRunThemAll.bat
CALL ScriptA.bat
CALL ScriptB.bat
EXIT

::ScriptA.bat
Do Foo

::ScriptB.bat
Do bar

我知道我参加晚会有点晚了，但这里有另一种方法。也就是说，这个方法应该等到第一个完成，第二个完成，依此类推。

start "" /wait cmd.exe /c msbuild.bat
start "" /wait cmd.exe /c unit-tests.bat
start "" /wait cmd.exe /c deploy.bat

使用此方法可能产生的唯一问题是，在生成新的cmd.exe实例时，每个cmd.exe实例中都保留了错误级别检查。

Or..

start "" /wait call msbuild.bat
start "" /wait call unit-tests.bat
start "" /wait call deploy.bat

希望这有帮助。

Start msbuild.bat
Start unit-tests.bat
Start deploy.bat

如果这不起作用，请用call替换start或尝试以下操作：

Start msbuild.bat
Goto :1
:1
Start unit-tests.bat
Goto :2
:2
Start deploy.bat

如果我们想打开多个命令提示符，那么可以使用

start cmd /k

/k： 强制执行。

可以按如下方式启动许多命令提示。

start cmd /k Call rc_hub.bat 4444

start cmd /k Call rc_grid1.bat 5555

start cmd /k Call rc_grid1.bat 6666

start cmd /k Call rc_grid1.bat 5570.