这个for循环将列出目录中的所有文件。

pushd somedir
for /f "delims=" %%f in ('dir /b /a-d-h-s') do echo %%f
popd

"delims="用于显示包含空格的长文件名....

'/b"只显示名称，不显示大小日期等。

关于dir's /a参数需要了解的一些事情。

使用“/a”会列出所有内容，包括隐藏属性和系统属性。 “/ad”只显示子目录，包括隐藏目录和系统目录。 "/a-d"参数消除带有'D'irectory属性的内容。 "/a-d-h-s"将显示所有内容，但包含'D'irectory， 'H'idden 'S'ystem属性的条目除外。

如果在命令行上使用此命令，请删除“%”。

希望这能有所帮助。

for %1 in (*.*) do echo %1

在cmd中尝试“HELP FOR”以获得完整的指南

这是XP命令的指南。http://www.ss64.com/nt/

从命令行运行FOR和从批处理文件运行FOR之间有细微的区别。在批处理文件中，您需要在每个变量引用前放置两个%字符。

从命令行:

FOR %i IN (*) DO ECHO %i

从批处理文件:

FOR %%i IN (*) DO ECHO %%i

在我的情况下，我必须删除临时文件夹下的所有文件和文件夹。这就是我最后做这件事的原因。我必须运行两个循环一个文件和一个文件夹。如果文件或文件夹名称中有空格，则必须使用" "

cd %USERPROFILE%\AppData\Local\Temp\
rem files only
for /r %%a in (*) do (
echo deleting file "%%a" ...
if exist "%%a" del /s /q "%%a"
)
rem folders only
for /D %%a in (*) do (
echo deleting folder "%%a" ...
if exist "%%a" rmdir /s /q "%%a"
)

%1是传入的第一个参数，不能在迭代器中使用。

试试这个:

@echo off
for %%i in (*.*) do echo %%i

我使用xcopy命令和/L选项来获取文件名。所以如果你想获取一个目录或子目录下的所有文件，你可以这样做:

for /f "delims=" %%a IN ('xcopy "D:\*.pdf" c:\ /l') do echo %%a

我只是使用c:\作为目标，因为它一直存在于windows系统中，而且它不会复制，所以没关系。如果你也想要子目录，只需在最后使用/s选项。如果出于其他原因需要xcopy的其他开关，也可以使用它们。