使用cmd.exe和

for /F "tokens=*" %F in (file.txt) do whatever "%F" ...

仅适用于“正常”文件。对于巨大的文件，它失败得很惨。

对于大文件，你可能需要使用Powershell和类似的东西:

[IO.File]::ReadLines("file.txt") | ForEach-Object { whatever "$_" }

或者如果你有足够的内存:

foreach($line in [System.IO.File]::ReadLines("file.txt")) { whatever "$line" } 

这对我来说是一个250 MB的文件，包含200多万行，其中for /F…命令行写了几千行就卡住了。

关于foreach和foreach - object的区别，请参见了解foreach和foreach - object。

(字幕:在PowerShell中逐行读取文件)

在批处理文件中，您必须使用%%而不是%:(键入help for)

for /F "tokens=1,2,3" %%i in (myfile.txt) do call :process %%i %%j %%k
goto thenextstep
:process
set VAR1=%1
set VAR2=%2
set VAR3=%3
COMMANDS TO PROCESS INFORMATION
goto :EOF

它的作用: for命令末尾的“do call:process %%i %%j %%k”将for命令从myfile.txt中获取的信息传递给“process”“子例程”。

当您在批处理程序中使用for命令时，您需要为变量使用双%符号。

下面几行将这些变量从for命令传递给进程“子例程”，并允许您处理这些信息。

set VAR1=%1
 set VAR2=%2
 set VAR3=%3

我有一些非常高级的使用这个确切的设置，如果需要更多的例子，我愿意分享。当然，根据需要添加您的EOL或Delims。

改进第一个“FOR /F..”的答案: 我要做的是调用执行MyList.txt中列出的每个脚本，所以它对我有用:

for /F "tokens=*" %A in  (MyList.txt) do CALL %A ARG1

——或者，如果你想在多行上做:

for /F "tokens=*" %A in  (MuList.txt) do (
ECHO Processing %A....
CALL %A ARG1
)

编辑:上面给出的例子是从命令提示符执行for循环;在批处理脚本中，需要添加一个额外的%，如下所示:

---START of MyScript.bat---
@echo off
for /F "tokens=*" %%A in  ( MyList.TXT) do  (
   ECHO Processing %%A.... 
   CALL %%A ARG1 
)
@echo on
;---END of MyScript.bat---

这是我写的一个bat文件来执行文件夹中的所有SQL脚本:

REM ******************************************************************
REM Runs all *.sql scripts sorted by filename in the current folder.
REM To use integrated auth change -U <user> -P <password> to -E
REM ******************************************************************

dir /B /O:n *.sql > RunSqlScripts.tmp
for /F %%A in (RunSqlScripts.tmp) do osql -S (local) -d DEFAULT_DATABASE_NAME -U USERNAME_GOES_HERE -P PASSWORD_GOES_HERE -i %%A
del RunSqlScripts.tmp

公认的答案是好的，但有两个局限性。 它删除空行和以;

要读取任何内容的行，您需要延迟展开切换技术。

@echo off
SETLOCAL DisableDelayedExpansion
FOR /F "usebackq delims=" %%a in (`"findstr /n ^^ text.txt"`) do (
    set "var=%%a"
    SETLOCAL EnableDelayedExpansion
    set "var=!var:*:=!"
    echo(!var!
    ENDLOCAL
)

Findstr用于用行号和冒号作为每行的前缀，因此空行不再是空的。

delayeexpansion需要被禁用，当访问%%a参数时，否则是感叹号!插入符号^将丢失，因为它们在该模式中具有特殊含义。

但是要从行中删除行号，需要启用延迟扩展。 设置"var=!var:*:=!"删除第一个冒号之前的所有冒号(使用delims=:也会删除一行开头的所有冒号，而不仅仅是findstr中的冒号)。 endlocal对下一行再次禁用延迟扩展。

唯一的限制现在是线长限制~8191，但似乎没有办法克服这一点。

从命令行打印文本文件中的所有行(使用delayeexpansion):

set input="path/to/file.txt"

for /f "tokens=* delims=[" %i in ('type "%input%" ^| find /v /n ""') do (
set a=%i
set a=!a:*]=]!
echo:!a:~1!)

适用于前导空白、空行、空白行。

在win10 CMD上测试