如果你有NT-family的Windows(使用cmd.exe作为shell)，试试FOR /F命令。

修改示例在这里列出我们的Rails应用程序在Heroku -谢谢!

cmd /C "heroku list > heroku_apps.txt"
find /v "=" heroku_apps.txt | find /v ".TXT" | findstr /r /v /c:"^$" > heroku_apps_list.txt
for /F "tokens=1" %%i in (heroku_apps_list.txt) do heroku run bundle show rails --app %%i

完整代码在这里。

改进第一个“FOR /F..”的答案: 我要做的是调用执行MyList.txt中列出的每个脚本，所以它对我有用:

for /F "tokens=*" %A in  (MyList.txt) do CALL %A ARG1

——或者，如果你想在多行上做:

for /F "tokens=*" %A in  (MuList.txt) do (
ECHO Processing %A....
CALL %A ARG1
)

编辑:上面给出的例子是从命令提示符执行for循环;在批处理脚本中，需要添加一个额外的%，如下所示:

---START of MyScript.bat---
@echo off
for /F "tokens=*" %%A in  ( MyList.TXT) do  (
   ECHO Processing %%A.... 
   CALL %%A ARG1 
)
@echo on
;---END of MyScript.bat---

这是我写的一个bat文件来执行文件夹中的所有SQL脚本:

REM ******************************************************************
REM Runs all *.sql scripts sorted by filename in the current folder.
REM To use integrated auth change -U <user> -P <password> to -E
REM ******************************************************************

dir /B /O:n *.sql > RunSqlScripts.tmp
for /F %%A in (RunSqlScripts.tmp) do osql -S (local) -d DEFAULT_DATABASE_NAME -U USERNAME_GOES_HERE -P PASSWORD_GOES_HERE -i %%A
del RunSqlScripts.tmp

@ kraus先生的回答很有启发性。另外，如果您想加载与批处理文件位于同一目录中的文件，请在文件名前加上%~dp0。这里有一个例子:

cd /d %~dp0
for /F "tokens=*" %%A in (myfile.txt) do [process] %%A

注意:如果你的文件名或目录(例如上面例子中的myfile.txt)有一个空格(例如:'my file.txt'或'c:\程序文件')，使用:

for /F "tokens=*" %%A in ('type "my file.txt"') do [process] %%A

，使用type关键字调用type程序，该程序显示文本文件的内容。如果您不想承受调用type命令的开销，您应该将目录更改为文本文件的目录。注意，带空格的文件名仍然需要type。

我希望这能帮助到一些人!

从Windows命令行引用:

要解析一个文件，忽略注释行，输入:

for /F "eol=; tokens=2,3* delims=," %i in (myfile.txt) do @echo %i %j %k

这个命令解析Myfile.txt中的每一行，忽略以分号开头的行，并将每行的第二和第三个标记传递给FOR主体(标记由逗号或空格分隔)。FOR语句体引用%i来获取第二个令牌，引用%j来获取第三个令牌，引用%k来获取所有剩余的令牌。

如果您提供的文件名包含空格，则在文本周围使用引号(例如，“文件名”)。要使用引号，必须使用usebackq。否则，引号将被解释为定义要解析的字面值字符串。

顺便说一下，你可以在大多数Windows系统上找到命令行帮助文件:

 "C:\WINDOWS\Help\ntcmds.chm"