这可以在SQL Server 2014+中完成，前提是存储过程只返回一个表。如果有人能为多张桌子找到这样的方法，我很想知道。

DECLARE @storedProcname NVARCHAR(MAX) = ''
SET @storedProcname = 'myStoredProc'

DECLARE @strSQL AS VARCHAR(MAX) = 'CREATE TABLE myTableName '

SELECT @strSQL = @strSQL+STUFF((
SELECT ',' +name+' ' + system_type_name 
FROM sys.dm_exec_describe_first_result_set_for_object (OBJECT_ID(@storedProcname),0)
FOR XML PATH('')
),1,1,'(') + ')'

EXEC (@strSQL)

INSERT INTO myTableName

EXEC ('myStoredProc @param1=1, @param2=2')

SELECT * FROM myTableName

DROP TABLE myTableName

这将从系统表中提取返回表的定义，并使用它为您构建临时表。然后，您可以如前所述从存储过程填充它。

还有一些变体也适用于动态SQL。

这是对您的问题稍作修改的答案。如果可以放弃对用户定义函数使用存储过程，则可以使用内联表值用户定义函数。这本质上是一个存储过程（将采用参数），它将表作为结果集返回；因此将与INTO语句一起放置。

这里有一篇关于它和其他用户定义函数的快速文章。如果仍然需要驱动存储过程，则可以用存储过程包装内联表值用户定义函数。存储过程在从内联表值用户定义函数调用select*时只传递参数。

例如，您可以使用一个内联表值用户定义函数来获取特定地区的客户列表：

CREATE FUNCTION CustomersByRegion 
(  
    @RegionID int  
)
RETURNS TABLE 
AS
RETURN 
  SELECT *
  FROM customers
  WHERE RegionID = @RegionID
GO

然后，您可以调用此函数来获取结果，例如：

SELECT * FROM CustomersbyRegion(1)

或执行SELECT INTO：

SELECT * INTO CustList FROM CustomersbyRegion(1)

如果仍然需要存储过程，则按如下方式包装函数：

CREATE PROCEDURE uspCustomersByRegion 
(  
    @regionID int  
)
AS
BEGIN
     SELECT * FROM CustomersbyRegion(@regionID);
END
GO

我认为这是获得理想结果的最“无黑客”的方法。它使用了现有的功能，因为它们的使用不会带来额外的复杂性。通过在存储过程中嵌套内联表值用户定义函数，您可以通过两种方式访问该功能。加实际SQL代码只有一个维护点。

已经建议使用OPENROWSET，但这不是OPENROWET函数的用途（摘自联机丛书）：

包括所有连接信息访问远程数据所需的来自OLE DB数据源。这方法是访问表，并且是一个一次性临时连接方法和使用OLE访问远程数据数据库。更频繁的参考OLE DB数据源，使用链接服务器。

使用OPENROWSET可以完成任务，但在打开本地连接和编组数据时会产生一些额外的开销。它也可能不是所有情况下的选项，因为它需要临时查询权限，这会带来安全风险，因此可能不需要。此外，OPENROWSET方法将排除使用返回多个结果集的存储过程。在单个存储过程中包装多个内联表值用户定义函数可以实现这一点。

我发现将数组/数据表传递到存储过程中，这可能会让您对如何解决问题有另一个想法。

该链接建议使用Image类型参数传递到存储过程中。然后在存储过程中，图像被转换为包含原始数据的表变量。

也许有一种方法可以用于临时表。

如果OPENROWSET给您带来问题，从2012年起还有另一种方法；使用sys.dm_exec_descript_first_result_set_for_object，如下所述：检索存储过程的列名和类型？

首先，创建此存储过程以生成临时表的SQL：

CREATE PROCEDURE dbo.usp_GetStoredProcTableDefinition(
    @ProcedureName  nvarchar(128),
    @TableName      nvarchar(128),
    @SQL            nvarchar(max) OUTPUT
)
AS
SET @SQL = 'CREATE TABLE ' + @tableName + ' ('

SELECT @SQL = @SQL + '['+name +'] '+ system_type_name +''  + ','
        FROM sys.dm_exec_describe_first_result_set_for_object
        (
          OBJECT_ID(@ProcedureName), 
          NULL
        );

--Remove trailing comma
SET @SQL = SUBSTRING(@SQL,0,LEN(@SQL))    
SET @SQL =  @SQL +')'

要使用该过程，请按以下方式调用它：

DECLARE     @SQL    NVARCHAR(MAX)

exec dbo.usp_GetStoredProcTableDefinition
    @ProcedureName='dbo.usp_YourProcedure',
    @TableName='##YourGlobalTempTable',@SQL = @SQL OUTPUT

INSERT INTO ##YourGlobalTempTable
EXEC    [dbo].usp_YourProcedure

select * from ##YourGlobalTempTable

注意，我使用的是全局临时表。这是因为使用EXEC运行动态SQL会创建自己的会话，因此普通临时表将超出任何后续代码的范围。如果全局临时表有问题，可以使用普通临时表，但任何后续SQL都需要是动态的，也就是说，也可以由EXEC语句执行。

这是一个简单的2步过程：-创建临时表-插入临时表。

执行相同操作的代码：

CREATE TABLE #tempTable (Column1 int, Column2 varchar(max));
INSERT INTO #tempTable 
EXEC [app].[Sproc_name]
@param1 = 1,
@param2 =2;

这是我的T-SQL和参数

--require one time execution if not configured before
sp_configure 'Show Advanced Options', 1
GO
RECONFIGURE
GO

--require one time execution if not configured before
sp_configure 'Ad Hoc Distributed Queries', 1
GO
RECONFIGURE
GO


--the query
DECLARE @param1 int = 1, @param2 int = 2
DECLARE @SQLStr varchar(max) = 'SELECT * INTO #MyTempTable
                                FROM OPENROWSET(''SQLNCLI'',  
''Server=ServerName;Database=DbName;Trusted_Connection=yes'',
''exec StoredProcedureName '+ CAST(@param1 AS varchar(15)) +','+ CAST(@param2 AS varchar(15)) +''') AS a ;
 select * from #MyTempTable;
 drop table #MyTempTable        
';
EXECUTE(@SQLStr);