我想在任何现有的#include之前，用一个额外的include指令更新大量的c++源文件。对于这类任务，我通常使用带有sed的小型bash脚本来重写文件。
我如何得到sed替换一个文件中字符串的第一次出现，而不是替换每一次出现?
如果我用
sed s/#include/#include "newfile.h"\n#include/
它替换所有#includes。
我们也欢迎为达到同样目的而提出的其他建议。
当前回答
#!/bin/sed -f
1,/^#include/ {
/^#include/i\
#include "newfile.h"
}
该脚本的工作原理:对于第1行和第一个#include(在第1行之后)之间的行，如果该行以#include开头，则在指定的行前面加上。
但是，如果第一个#include在第1行，那么第1行和下一个#include都将有该行前置。如果您正在使用GNU sed，它有一个扩展，其中0，/^#include/(而不是1，)将做正确的事情。
其他回答
POSIXly(在sed中也有效)，只使用一个正则表达式，只需要一行内存(和往常一样):
sed '/\(#include\).*/!b;//{h;s//\1 "newfile.h"/;G};:1;n;b1'
解释道:
sed '
/\(#include\).*/!b # Only one regex used. On lines not matching
# the text `#include` **yet**,
# branch to end, cause the default print. Re-start.
//{ # On first line matching previous regex.
h # hold the line.
s//\1 "newfile.h"/ # append ` "newfile.h"` to the `#include` matched.
G # append a newline.
} # end of replacement.
:1 # Once **one** replacement got done (the first match)
n # Loop continually reading a line each time
b1 # and printing it by default.
' # end of sed script.
一个可能的解决方案:
/#include/!{p;d;}
i\
#include "newfile.h"
:a
n
ba
解释:
读取行，直到找到#include，打印这些行，然后开始新的循环 插入新的包含行 输入一个只读取行(默认情况下sed也会打印这些行)的循环，我们不会从这里回到脚本的第一部分
只需要在最后加上出现的次数:
sed s/#include/#include "newfile.h"\n#include/1
我需要一个在GNU和BSD上都可以工作的解决方案，而且我也知道第一行永远不会是我需要更新的一行:
sed -e "1,/pattern/s/pattern/replacement/"
尝试//特性不重复模式对我不起作用，因此需要重复它。
如果有人来这里替换所有行中第一次出现的字符(比如我自己)，使用这个:
sed '/old/s/old/new/1' file
-bash-4.2$ cat file
123a456a789a
12a34a56
a12
-bash-4.2$ sed '/a/s/a/b/1' file
123b456a789a
12b34a56
b12
例如，通过将1改为2，你可以只替换所有的第二个a。
