如何在批处理文件中回显换行符?

如何从批处理文件输出中插入换行符?

我想做的事情是:

echo hello\nworld

这将输出:

hello
world

当前回答

这对我来说很有效，不需要延迟扩展:

@echo off
(
echo ^<html^> 
echo ^<body^>
echo Hello
echo ^</body^>
echo ^</html^>
)
pause

它像这样写输出:

<html>
<body>
Hello
</body>
</html>
Press any key to continue . . .

2010-06-02 15:35:47

其他回答

简单的

set nl=.
echo hello
echo%nl%
REM without space ^^^
echo World

结果:

hello
world

2021-04-30 04:04:44

你也可以这样做，

(for %i in (a b "c d") do @echo %~i)

输出将是，

a
b
c d

请注意，当将其放入批处理文件中时，'%'应该加倍。

(for %%i in (a b "c d") do @echo %%~i)

2011-09-20 17:06:29

如果有人来这里是因为他们想从MINGW make makefile中回显一个空行，我使用

@cmd /c echo。

简单地使用echo。导致可怕的process_begin: CreateProcess(NULL, echo。，…)失败了。错误消息。

我希望这能帮助到至少一个人:)

2013-04-22 04:56:19

在这里，创建一个.bat文件，其中包含以下内容:

@echo off
REM Creating a Newline variable (the two blank lines are required!)
set NLM=^


set NL=^^^%NLM%%NLM%^%NLM%%NLM%
REM Example Usage:
echo There should be a newline%NL%inserted here.

echo.
pause

您应该会看到如下输出:

There should be a newline
inserted here.

Press any key to continue . . .

显然，您只需要REM语句之间的代码。

2008-11-06 18:43:45

就像肯的答案一样，只是用了延迟扩展。

setlocal EnableDelayedExpansion
(set \n=^
%=Do not remove this line=%
)

echo Line1!\n!Line2
echo Works also with quotes "!\n!line2"

First a single linefeed character is created and assigned to the \n-variable. This works as the caret at the line end tries to escape the next character, but if this is a Linefeed it is ignored and the next character is read and escaped (even if this is also a linefeed). Then you need a third linefeed to end the current instruction, else the third line would be appended to the LF-variable. Even batch files have line endings with CR/LF only the LF are important, as the CR's are removed in this phase of the parser.

使用延迟展开的优点是，根本不需要进行特殊的字符处理。 Line1%LF%Line2将失败，因为解析器在单个换行处停止解析。

更多解释见 SO:在Vista/DOS批处理(.bat)文件中，长命令拆分为多行那么:Windows命令解释器(CMD.EXE)如何解析脚本?

编辑:避免回声。

这并没有回答问题，因为问题是关于单个echo可以输出多行。

但是除了其他答案谁建议使用回声。要创建新行，应注意echo。是最糟糕的，因为它非常慢，它可以完全失败，因为cmd.exe搜索一个名为ECHO的文件，并试图启动它。

如果只打印空行，可以使用其中之一

echo,
echo;
echo(
echo/
echo+
echo=

而是回声的使用。， echo\或echo:应该避免，因为它们会非常慢，这取决于脚本执行的位置，比如网络驱动器。

2011-06-16 23:52:05

如何在批处理文件中回显换行符?

推荐文章

最新文章

标签