我刚刚看到这个问题，无法帮助发布我的自动热键脚本在Windows XP上的cmd。您可以在脚本中找到热键。好的事情是，当你当前的窗口是资源管理器时，cmd将在地址栏显示的路径中打开。

我把这个脚本保存在存放所有绿色工具(包括自动热键)的文件夹中。对于一台新机器，我只需复制文件夹，双击脚本将.ahk与AutoHotkey关联起来，并在启动文件夹中创建一个快捷方式。它比安装PowerToys还要快。

; Get working folder
GetWorkingFolder() {
    if WinActive("ahk_class ExploreWClass") or WinActive("ahk_class CabinetWClass") {
        ControlGetText, path, Edit1
        return %path%
    } else if WinActive("FreeCommander") {
        Send, {CTRLDOWN}{ALTDOWN}{INS}{ALTUP}{CTRLUP}
        Sleep, 100
        return clipboard
    } else {
        return "C:\"
    }
}

#IfWinActive,

#c::
    path := GetWorkingFolder()
    Run, %ComSpec%, %path%
    return

; PowerShell
#+C::
    path := GetWorkingFolder()
    Run, %SystemRoot%\system32\WindowsPowerShell\v1.0\powershell.exe, %path%
    return

#^c::
    Run, %ComSpec%, %temp%
    return

#!c::
    path := GetWorkingFolder()
    Run, %comspec% /k "%VS90COMNTOOLS%vsvars32.bat", %path%
    return

; irb
#!b::
    path := GetWorkingFolder()
    Run, c:\cygwin\bin\ruby /usr/bin/irb, %path%
    return

; Bash
#b::
    path := GetWorkingFolder()
    Run, bash --login, %path%
    return

; Paste in console
+INS::
    if WinActive("ahk_class ConsoleWindowClass") {
        WinGetPos, x, y, w, h, A
        MouseGetPos, mx, my
        ;MsgBox x=%x% y=%y% w=%w% h=%h% mx=%mx% my=%my%
        if (mx < 10)
            mx = 10
        else if (mx > w - 30)
            mx := w - 30

        if (my < 40)
            my = 40
        else if (my > h)
            my := h - 10

        MouseClick, right, mx, my
    }
    return

对于任何感兴趣的人，你可以在github上的rwin上找到这个脚本

创建一个快捷方式，并编辑快捷方式的“Start In”属性到您想要cmd.exe启动的目录。

在Windows资源管理器- shift +鼠标右键点击上面的文件夹“打开命令窗口这里”选项显示在菜单中。或在您的Windows版本的语言。

这个程序总是在浏览器的当前路径下打开cmd.exe: https://github.com/jhasse/smart_cmd

你也可以把它固定在你的任务栏上，然后使用WindowsKey+[1-0]作为键盘快捷键。

另外，这里有一个在任何windows文件夹中打开控制台的快捷方式:

在windows资源管理器上打开任何文件夹。 按Alt + D聚焦地址栏 输入CMD，按“enter”

非常实用的捷径。

Pushd命令设置当前文件夹。所以:

cmd /k "pushd D:\Music"