以下两项都不是真正的顽固，但我发现它非常有用。

琐碎的捆绑，但我不能没有。它在插入模式下启用hjkl风格的移动（使用ctrl键）。在正常模式下：ctrl-k/j向上/向下滚动半个屏幕，ctrl-l/h转到下一个/上一个缓冲区。µ和ù映射特别适用于AZERTY键盘，并转到下一个/上一个错误。

imap <c-j> <Down>
imap <c-k> <Up>
imap <c-h> <Left>
imap <c-l> <Right>
nmap <c-j> <c-d>
nmap <c-k> <c-u>
nmap <c-h> <c-left>
nmap <c-l> <c-right>

nmap ù :cp<RETURN>
nmap µ :cn<RETURN>

我编写了一个小函数来突出显示函数、全局、宏、结构和typedef。（对于非常大的文件可能会很慢）。每种类型都有不同的突出显示（请参阅“：help group name”了解当前颜色主题的设置）用法：使用ww（默认“\ww”）保存文件。你需要做这个。

nmap <Leader>ww :call SaveCtagsHighlight()<CR>

"Based on: http://stackoverflow.com/questions/736701/class-function-names-highlighting-in-vim
function SaveCtagsHighlight()
    write

    let extension = expand("%:e")
    if extension!="c" && extension!="cpp" && extension!="h" && extension!="hpp"
        return
    endif

    silent !ctags --fields=+KS *
    redraw!

    let list = taglist('.*')
    for item in list
        let kind = item.kind

        if     kind == 'member'
            let kw = 'Identifier'
        elseif kind == 'function'
            let kw = 'Function'
        elseif kind == 'macro'
            let kw = 'Macro'
        elseif kind == 'struct'
            let kw = 'Structure'
        elseif kind == 'typedef'
            let kw = 'Typedef'
        else
            continue
        endif

        let name = item.name
        if name != 'operator=' && name != 'operator ='
            exec 'syntax keyword '.kw.' '.name
        endif
    endfor
    echo expand("%")." written, tags updated"
endfunction

我有编写大量代码和函数的习惯，我不喜欢为它们编写原型。所以我做了一些函数，在C样式源文件中生成原型列表。它有两种风格：一种是删除形式参数的名称，另一种是保留它。每次需要更新原型时，我都会刷新整个列表。它避免了原型和函数定义不同步。还需要ctags。

"Usage: in normal mode, where you want the prototypes to be pasted:
":call GenerateProptotypes()
function GeneratePrototypes()
    execute "silent !ctags --fields=+KS ".expand("%")
    redraw!
    let list = taglist('.*')
    let line = line(".")
    for item in list
        if item.kind == "function"  &&  item.name != "main"
            let name = item.name
            let retType = item.cmd
            let retType = substitute( retType, '^/\^\s*','','' )
            let retType = substitute( retType, '\s*'.name.'.*', '', '' ) 

            if has_key( item, 'signature' )
                let sig = item.signature
                let sig = substitute( sig, '\s*\w\+\s*,',        ',',   'g')
                let sig = substitute( sig, '\s*\w\+\(\s)\)', '\1', '' )
            else
                let sig = '()'
            endif
            let proto = retType . "\t" . name . sig . ';'
            call append( line, proto )
            let line = line + 1
        endif
    endfor
endfunction


function GeneratePrototypesFullSignature()
    "execute "silent !ctags --fields=+KS ".expand("%")
    let dir = expand("%:p:h");
    execute "silent !ctags --fields=+KSi --extra=+q".dir."/* "
    redraw!
    let list = taglist('.*')
    let line = line(".")
    for item in list
        if item.kind == "function"  &&  item.name != "main"
            let name = item.name
            let retType = item.cmd
            let retType = substitute( retType, '^/\^\s*','','' )
            let retType = substitute( retType, '\s*'.name.'.*', '', '' ) 

            if has_key( item, 'signature' )
                let sig = item.signature
            else
                let sig = '(void)'
            endif
            let proto = retType . "\t" . name . sig . ';'
            call append( line, proto )
            let line = line + 1
        endif
    endfor
endfunction

全部替换

  :%s/oldtext/newtext/igc

给出一个替换所有：）

:r! <command>

将外部命令的输出粘贴到缓冲区中。

做一些数学运算，直接在文本中得到结果：

:r! echo $((3 + 5 + 8))

获取编写Makefile时要编译的文件列表：

:r! ls *.c

不要在维基百科上查找你阅读的事实，直接将其粘贴到你正在编写的文档中：

:r! lynx -dump http://en.wikipedia.org/wiki/Whatever

不确定这是否算是黑暗角落，但我只是刚刚学会了。。。

:g/match/y A

将把所有包含“match”的行拖（复制）到“a/@a”寄存器中。（大写字母a使vim附加了“yankings”，而不是替换之前的寄存器内容。）我最近在制作Internet Explorer样式表时经常使用它。

我最近发现了一件我觉得很酷的事：

:earlier 15m

将文档还原为15分钟前的状态。可以为您想要回滚的时间量提供各种参数，并且取决于撤消级别。可以用相反的命令反转：稍后

我确信有人已经发布了这篇文章，但这里是这样的。

请选择任何构建系统；制造，mvn，蚂蚁，随便什么。在项目目录的根目录中，创建一个始终使用的命令文件，如下所示：

根项目上进行构建mvn清洁安装等等

要进行构建，请将光标放在线上并键入！！即过滤该线路；将其写入shell并替换为结果。

构建日志将替换行，随时可以滚动、搜索等。

查看完日志后，键入u以撤消，然后返回命令文件。