从这里获取unxutils：http://sourceforge.net/projects/unxutils/

在windows平台上的黄金，将所有漂亮的unix实用程序放在标准的windows DOS上。多年来一直在使用它。

它包含一个“which”。注意，它是区分大小写的。

注意：要安装它，请在某个地方爆炸拉链并添加。。。\将xUtils\usr\local\wbin\解压缩到系统路径env变量。

Cygwin是一个解决方案。如果您不介意使用第三方解决方案，那么Cygwin就是您的选择。

Cygwin在Windows环境中为您提供了*nix的舒适性（您可以在Windows命令shell中使用它，也可以选择使用*nix shell）。它为您提供了一整套适用于Windows的*nix命令（如），您可以将该目录包含在PATH中。

此批处理文件使用CMD变量处理来查找将在路径中执行的命令。注意：当前目录总是在路径之前完成），并且根据使用的API调用，在路径之前/之后搜索其他位置。

@echo off
echo. 
echo PathFind - Finds the first file in in a path
echo ======== = ===== === ===== ==== == == = ====
echo. 
echo Searching for %1 in %path%
echo. 
set a=%~$PATH:1
If "%a%"=="" (Echo %1 not found) else (echo %1 found at %a%)

参见集合/？寻求帮助。

GnuWin32工具以及一系列其他Unix工具都有。

虽然较新版本的Windows具有where命令，但您也可以使用环境变量修饰符在Windows XP中执行此操作，如下所示：

c:\> for %i in (cmd.exe) do @echo.   %~$PATH:i
   C:\WINDOWS\system32\cmd.exe

c:\> for %i in (python.exe) do @echo.   %~$PATH:i
   C:\Python25\python.exe

您不需要任何额外的工具，也不限于PATH，因为您可以替换任何您希望使用的环境变量（当然是路径格式）。

而且，如果你想要一个能够处理PATHEXT中所有扩展的系统（就像Windows本身一样），这个系统可以做到：

@echo off
setlocal enableextensions enabledelayedexpansion

:: Needs an argument.

if "x%1"=="x" (
    echo Usage: which ^<progName^>
    goto :end
)

:: First try the unadorned filenmame.

set fullspec=
call :find_it %1

:: Then try all adorned filenames in order.

set mypathext=!pathext!
:loop1
    :: Stop if found or out of extensions.

    if "x!mypathext!"=="x" goto :loop1end

    :: Get the next extension and try it.

    for /f "delims=;" %%j in ("!mypathext!") do set myext=%%j
    call :find_it %1!myext!

:: Remove the extension (not overly efficient but it works).

:loop2
    if not "x!myext!"=="x" (
        set myext=!myext:~1!
        set mypathext=!mypathext:~1!
        goto :loop2
    )
    if not "x!mypathext!"=="x" set mypathext=!mypathext:~1!

    goto :loop1
:loop1end

:end
endlocal
goto :eof

:: Function to find and print a file in the path.

:find_it
    for %%i in (%1) do set fullspec=%%~$PATH:i
    if not "x!fullspec!"=="x" @echo.   !fullspec!
    goto :eof

它实际上返回所有可能性，但您可以很容易地针对特定搜索规则进行调整。

我正在使用GOW（Windows上的GNU），这是Cygwin的一个轻量级版本。你可以在这里从GitHub获取它。

GOW（Windows上的GNU）是Cygwin的轻量级替代品。它使用一个方便的Windows安装程序，可安装大约130个编译为本机win32的有用的开源UNIX应用程序二进制文件。它设计得尽可能小，大约10 MB与Cygwin相反，Cygwin可以运行超过100 MB，这取决于选项。-关于描述（Brent R.Matzelle）

GOW中包含的命令列表截图：