我认为最简单的方法是以下步骤，你不需要安装任何软件包或软件:

首先，你找出你想知道的用户组的GID，有很多方法: cat /etc/group(最后一列是GID) Id用户(用户是属于组的人) 现在，您将在文件/etc/passwd中列出所有用户，但是您将使用以下后续命令应用一些过滤器，以获得前一个组的成员。

cut -d: -f1,4 /etc/passwd |grep GID (GID是你从步骤1中得到的数字)

切命令将选择一些“列”的文件,参数d设置分隔符”:“在这种情况下,参数- f选择“字段”(或列)在案例1和4所示(在/ etc / passwd文件,1º列是用户的名称和4º是用户所属的组的GID),完成| grep GID将滤波器组(4º列),你选择了。

下面是另一个Python一行程序，它考虑了用户的默认组成员(来自/etc/passwd)以及组数据库(/etc/group)

python -c "import grp,pwd; print set(grp.getgrnam('mysupercoolgroup')[3]).union([u[0] for u in pwd.getpwall() if u.pw_gid == grp.getgrnam('mysupercoolgroup')[2]])"

你可以在一个命令行中完成:

cut -d: -f1,4 /etc/passwd | grep $(getent group <groupname> | cut -d: -f3) | cut -d: -f1

上面的命令列出了所有使用groupname作为主组的用户

如果还希望列出具有groupname的用户作为次要组，则使用以下命令

getent group <groupname> | cut -d: -f4 |  tr ',' '\n'

不幸的是，据我所知，没有好的、可移植的方法来做到这一点。如果您尝试解析/etc/group，就像其他人建议的那样，您将会错过那些将该组作为主要组的用户，以及通过UNIX平面文件以外的机制(即LDAP、NIS、pam-pgsql等)添加到该组的任何用户。

如果我必须自己做这件事，我可能会反过来做:使用id获取系统上每个用户的组(这将拉出对NSS可见的所有源)，并使用Perl或类似的东西为发现的每个组维护一个哈希表，并指出该用户的成员。

编辑:当然，这给您留下了一个类似的问题:如何获得系统上每个用户的列表。由于我的位置只使用平面文件和LDAP，所以我只能从两个位置获得一个列表，但对于您的环境可能是这样，也可能不是这样。

编辑2:有人提醒我，getent passwd将返回系统中所有用户的列表，包括来自LDAP/NIS/等的用户。，但getent组仍然会错过仅通过默认组条目成为成员的用户，所以这激发了我写这个快速破解。

#!/usr/bin/perl -T
#
# Lists members of all groups, or optionally just the group
# specified on the command line
#
# Copyright © 2010-2013 by Zed Pobre (zed@debian.org or zed@resonant.org)
#
# Permission to use, copy, modify, and/or distribute this software for any
# purpose with or without fee is hereby granted, provided that the above
# copyright notice and this permission notice appear in all copies.
#

use strict; use warnings;

$ENV{"PATH"} = "/usr/bin:/bin";

my $wantedgroup = shift;

my %groupmembers;
my $usertext = `getent passwd`;

my @users = $usertext =~ /^([a-zA-Z0-9_-]+):/gm;

foreach my $userid (@users)
{
    my $usergrouptext = `id -Gn $userid`;
    my @grouplist = split(' ',$usergrouptext);

    foreach my $group (@grouplist)
    {
        $groupmembers{$group}->{$userid} = 1;
    }
}

if($wantedgroup)
{
    print_group_members($wantedgroup);
}
else
{
    foreach my $group (sort keys %groupmembers)
    {
        print "Group ",$group," has the following members:\n";
        print_group_members($group);
        print "\n";
    }
}

sub print_group_members
{
    my ($group) = @_;
    return unless $group;

    foreach my $member (sort keys %{$groupmembers{$group}})
    {
        print $member,"\n";
    }
}

下面的命令将列出属于<your_group_name>的所有用户，但只列出由/etc/group数据库管理的用户，不包括LDAP、NIS等。它也只适用于次要组，它不会列出将该组设置为主要组的用户，因为主要组存储为/etc/passwd.文件中的GID(数字组ID)

awk -F: '/^groupname/ {print $4;}' /etc/group

我所做的与上面的perl代码类似，但是用本地perl函数替换了getent和id。它要快得多，应该可以跨不同的*nix口味工作。

#!/usr/bin/env perl

use strict;
my $arg=shift;
my %groupMembers; # defining outside of function so that hash is only built once for multiple function calls

sub expandGroupMembers{
my $groupQuery=shift;
unless (%groupMembers){
    while (my($name,$pass,$uid,$gid,$quota,$comment,$gcos,$dir,$shell,$expire)=getpwent()) {
            my $primaryGroup=getgrgid($gid);
            $groupMembers{$primaryGroup}->{$name}=1;
    }
    while (my($gname,$gpasswd,$gid,$members)=getgrent()) {
            foreach my $member (split / /, $members){
                    $groupMembers{$gname}->{$member}=1;
            }
    }
}
my $membersConcat=join(",",sort keys %{$groupMembers{$groupQuery}});
return "$membersConcat" || "$groupQuery Does have any members";
}
print &expandGroupMembers($arg)."\n";