如果你想保持你的\t等于8个空格，然后考虑设置:

   set softtabstop=2 tabstop=8 shiftwidth=2

这将给你两个空格，每<TAB>按下，但实际\t在你的代码中仍将被视为8个字符。

如果你使用makefile或其他文本文件，需要真正的制表符，而不是一些空格， 首先在~/vimrc中添加set noexpandtab， 或者直接输入set noexpandtab命令， 用vi(vim)编辑文件时

一旦你得到expandtab作为其他答案，根据你的新设置转换现有文件的极其方便的方法是:

:retab

它将在当前缓冲区上工作。

gg=G将重新缩进整个文件，并删除我从同事那里获得的文件中的大部分(如果不是全部的话)选项卡。

本文提供了一个出色的vimrc脚本，用于处理制表符+空格，并在它们之间进行转换。

提供以下命令: 将空格转换为制表符，只能缩进。 Tab2Space将制表符转换为空格，只能缩进。 RetabIndent执行Space2Tab(如果'expandtab'被设置)，或Tab2Space(否则)。 每个命令接受一个参数，该参数指定制表符列中的空格数。默认情况下，使用'tabstop'设置。

来源:http://vim.wikia.com/wiki/Super_retab脚本

" Return indent (all whitespace at start of a line), converted from
" tabs to spaces if what = 1, or from spaces to tabs otherwise.
" When converting to tabs, result has no redundant spaces.
function! Indenting(indent, what, cols)
  let spccol = repeat(' ', a:cols)
  let result = substitute(a:indent, spccol, '\t', 'g')
  let result = substitute(result, ' \+\ze\t', '', 'g')
  if a:what == 1
    let result = substitute(result, '\t', spccol, 'g')
  endif
  return result
endfunction

" Convert whitespace used for indenting (before first non-whitespace).
" what = 0 (convert spaces to tabs), or 1 (convert tabs to spaces).
" cols = string with number of columns per tab, or empty to use 'tabstop'.
" The cursor position is restored, but the cursor will be in a different
" column when the number of characters in the indent of the line is changed.
function! IndentConvert(line1, line2, what, cols)
  let savepos = getpos('.')
  let cols = empty(a:cols) ? &tabstop : a:cols
  execute a:line1 . ',' . a:line2 . 's/^\s\+/\=Indenting(submatch(0), a:what, cols)/e'
  call histdel('search', -1)
  call setpos('.', savepos)
endfunction

command! -nargs=? -range=% Space2Tab call IndentConvert(<line1>,<line2>,0,<q-args>)
command! -nargs=? -range=% Tab2Space call IndentConvert(<line1>,<line2>,1,<q-args>)
command! -nargs=? -range=% RetabIndent call IndentConvert(<line1>,<line2>,&et,<q-args>)

当我第一次寻找解决方案时，这比这里的答案对我的帮助要大一些。

将以下行添加到.vimrc中

set expandtab
set tabstop=4
set shiftwidth=4
map <F2> :retab <CR> :wq! <CR>

在vim中打开一个文件，按F2 标签将转换为4个空间和文件将被自动保存。