我在这里找到了答案。

在我的.vimrc文件中添加以下内容就成功了:

autocmd BufWritePre *.py :%s/\s\+$//e

末尾的标志表示如果搜索模式失败，该命令不会发出错误消息。。更多信息请参见:h:s_flags。

我就是这么做的。我不记得从哪里偷来的了。

autocmd BufWritePre * :call <SID>StripWhite()
fun! <SID>StripWhite()
    %s/[ \t]\+$//ge
    %s!^\( \+\)\t!\=StrRepeat("\t", 1 + strlen(submatch(1)) / 8)!ge
endfun

我在这里找到了答案。

在我的.vimrc文件中添加以下内容就成功了:

autocmd BufWritePre *.py :%s/\s\+$//e

末尾的标志表示如果搜索模式失败，该命令不会发出错误消息。。更多信息请参见:h:s_flags。

如果要删除空白，应该只对已经是干净的文件进行处理。“在罗马的时候……”在不欢迎虚假更改的代码库上工作时，这是一种良好的礼仪。

此函数检测尾随空格，并仅在已经清除的情况下开启修剪。

这个想法的功劳来自这里的一个评论:https://github.com/atom/whitespace/issues/10(有史以来最长的bug票评论流)

autocmd BufNewFile,BufRead *.test call KarlDetectWhitespace()

fun! KarlDetectWhitespace()
python << endpython
import vim
nr_unclean = 0
for line in vim.current.buffer:
    if line.rstrip() != line:
        nr_unclean += 1

print "Unclean Lines: %d" % nr_unclean
print "Name: %s" % vim.current.buffer.name
cmd = "autocmd BufWritePre <buffer> call KarlStripTrailingWhitespace()"
if nr_unclean == 0:
    print "Enabling Whitespace Trimming on Save"
    vim.command(cmd)
else:
    print "Whitespace Trimming Disabled"
endpython
endfun

fun! KarlStripTrailingWhitespace()
    let l = line(".")
    let c = col(".")
    %s/\s\+$//e
    call cursor(l, c)
endfun

编译以上加上保存光标位置:

function! <SID>StripTrailingWhitespaces()
  if !&binary && &filetype != 'diff'
    let l:save = winsaveview()
    keeppatterns %s/\s\+$//e
    call winrestview(l:save)
  endif
endfun

autocmd FileType c,cpp,java,php,ruby,python autocmd BufWritePre <buffer> :call <SID>StripTrailingWhitespaces()

如果你想在保存到任何文件时应用此命令，请省略第二个autocmd并使用通配符*:

autocmd BufWritePre,FileWritePre,FileAppendPre,FilterWritePre *
  \ :call <SID>StripTrailingWhitespaces()

我通常也有一个:

match Todo /\s\+$/

在我的.vimrc文件中，使行末空格高亮显示。

Todo是一个语法高亮组名，用于高亮Todo、FIXME或XXX等关键字。它有一个讨厌的丑陋的黄色背景色，我发现它是最好的突出你不想在你的代码中的东西:-)