我对这个问题的所有其他答案都感到沮丧，因为没有一个答案能以有用的方式突出空间特征。将空格显示为字符对于空格格式的语言特别有用，因为混合制表符和空格是有害的。

我的解决方案是显示制表符并在多个空格下加下划线。它借鉴了mrucci的答案和本教程。因为它使用语法高亮显示，所以它是持久的：

set list listchars=tab:\|\ 
highlight Whitespace cterm=underline gui=underline ctermbg=NONE guibg=NONE ctermfg=yellow guifg=yellow
autocmd ColorScheme * highlight Whitespace gui=underline ctermbg=NONE guibg=NONE ctermfg=yellow guifg=yellow
match Whitespace /  \+/

使用此选项，制表符显示为|，空格显示为_，这使得在混合代码样式时很容易分辨。

我发现的唯一缺点是，这段代码没有调整背景颜色以匹配上下文（如注释中）。

上面的所有答案都试图使vim中的空间可见。如果你真的坚持将可见空间作为点，还有另一种方法。。。

如果无法在vim中完成，请完全更改字体。我复制了Ubuntu One Mono字体，并使用FontForge进行了编辑。记住要更改字体的全名、字体族、首选字体族、兼容字体（在FontFoge中，它位于字体信息中的TTF名称下），以便将其作为单独的字体。只需编辑空格字符，使其中间有一个点，然后将字体保存到~/.fonts现在你可以把它用于你的gvim或整个终端。。。我复制了“！”字符，删除了行并将点移到中间。花了5分钟多一点。。。

注意：更改空格字符（0x20）会导致在整个vim屏幕上出现点的不便。。。（但它将分隔空格和制表符…）

如果设置：

:highlight Search cterm=underline gui=underline ctermbg=none guibg=none ctermfg=none guifg=none

然后搜索空格，每个空格字符将显示为下划线字符。

您可以在切换空格“下划线”的便捷函数中使用此命令。

set hls
let g:HLSpace = 1
let g:HLColorScheme = g:colors_name
function ToggleSpaceUnderscoring()
    if g:HLSpace
        highlight Search cterm=underline gui=underline ctermbg=none guibg=none ctermfg=none guifg=none
        let @/ = " "
    else
        highlight clear
        silent colorscheme "".g:HLColorScheme
        let @/ = ""
    endif
    let g:HLSpace = !g:HLSpace
endfunction

将功能映射到快捷键，快捷键包括：

nmap <silent> <F3> <Esc>:call ToggleSpaceUnderscoring()<CR>

注意：设置配色方案后，在vimrc中定义函数。

:match CursorLine /\s\+/

避免了“必须搜索空间才能显示”这一点，但afaict不能配置为对空间进行非隐藏操作。CursorLine可以是任何照明组，在默认主题中它是一个普通下划线。

从补丁7.4.710开始，您现在可以使用listchars设置一个字符来代替空格！

:set listchars+=space:␣

因此，要将所有空白字符显示为字符，可以执行以下操作：

:set listchars=eol:¬,tab:>·,trail:~,extends:>,precedes:<,space:␣
:set list

完成后，要隐藏不可见的字符，请执行以下操作：

:set nolist

关于邮件列表的讨论：https://groups.google.com/forum/?fromgroups#!主题/vim_dev/pjmW6wOZW_Q

下面的代码基于Christian Brabandt的答案，似乎可以按照OP的要求执行：

function! Whitespace()
    if !exists('b:ws')
        highlight Conceal ctermbg=NONE ctermfg=240 cterm=NONE guibg=NONE guifg=#585858 gui=NONE
        highlight link Whitespace Conceal
        let b:ws = 1
    endif

    syntax clear Whitespace
    syntax match Whitespace / / containedin=ALL conceal cchar=·
    setlocal conceallevel=2 concealcursor=c
endfunction

augroup Whitespace
    autocmd!
    autocmd BufEnter,WinEnter * call Whitespace()
augroup END

将这些行添加到~/.vimrc并开始新的Vim会话，以查看仍然不完美的魔术发生。

随意编辑默认颜色和隐藏字符。

注意：几种语言中*FuncBody语法组中的某些内容会阻止显示中间点。我还不知道如何使该解决方案更可靠。