获取谷歌Sheets中列中的最后一个非空单元格

我使用下面的函数

=DAYS360(A2, A35)

计算我列中两个日期的差值。然而，列一直在扩大，我目前必须手动更改“A35”，因为我更新了我的电子表格。

是否有一种方法(在谷歌表)找到该列中的最后一个非空单元格，然后在上面的函数中动态设置该参数?

当前回答

我最喜欢:

=INDEX(A2:A,COUNTA(A2:A),1)

所以，对于OP的需求:

=DAYS360(A2,INDEX(A2:A,COUNTA(A2:A),1))

其他回答

计算列A中的最新日期与单元格A2中的日期之间的差值。

=MAX(A2:A)-A2

我最喜欢:

=INDEX(A2:A,COUNTA(A2:A),1)

所以，对于OP的需求:

=DAYS360(A2,INDEX(A2:A,COUNTA(A2:A),1))

也许还有更有说服力的方法，但这是我想到的方法:

查找列中最后一个填充单元格的函数是:

=INDEX( FILTER( A:A ; NOT( ISBLANK( A:A ) ) ) ; ROWS( FILTER( A:A ; NOT( ISBLANK( A:A ) ) ) ) )

所以如果你把它和你当前的函数结合起来，它会是这样的:

=DAYS360(A2,INDEX( FILTER( A:A ; NOT( ISBLANK( A:A ) ) ) ; ROWS( FILTER( A:A ; NOT( ISBLANK( A:A ) ) ) ) ))

通过LAMBDA和REDUCE函数的引入，我们现在可以在一次遍历单元格中计算行号(上面的几个解决方案过滤了两次范围)，而不依赖于神奇的文本或数值。

=lambda(rng, 
   REDUCE(0, rng, lambda(maxrow, cell, if(isblank(cell),maxrow,row(cell)) ) )
)(A:A)

它可以很好地打包成一个命名函数的用法，如

=LAST_ROWNUM(A:A)

它适用于具有穿插空格的列、多列范围(因为REDUCE在行优先的范围内迭代)和部分列(如A20:A)，仍然返回实际的行号(而不是范围内的偏移量)。

然后可以将其与Index组合以返回值

=DAYS360(A2, Index(A1, LAST_ROWNUM(A:A)))

(事实上，我怀疑OPs日期值是单调的(即使中间有空格)，他可以侥幸逃脱

=DAYS360(A2, MAX(A2:A))

上面的解决方案是依赖于“连续”的日期——这是否意味着“没有空白”或“没有缺失日期”我不确定——但这两种规定都是不必要的。)

这将给出最后一个单元格的内容:

=indirect("A"&max(ARRAYFORMULA(row(a:a)*--(a:a<>""))))

这将给出最后一个单元格的地址:

="A"&max(ARRAYFORMULA(row(a:a)*--(a:a<>"")))

这将给出最后一个单元格的行:

=max(ARRAYFORMULA(row(a:a)*--(a:a<>"")))

也许你更喜欢脚本。这个脚本比上面其他人发布的大脚本要短得多:

进入脚本编辑器，保存脚本:

function getLastRow(range){
  while(range.length>0 && range[range.length-1][0]=='') range.pop();
  return range.length;
}

完成后，你只需要在一个单元格中输入这个:

=getLastRow(A:A)

推荐文章